☰

Как заставить Outlook автоматически заполнять информацию?

tag-icon • tag-icon microsoft-outlook microsoft-outlook-2010
Как заставить Outlook автоматически заполнять информацию?

Мне постоянно приходится отправлять письма, которые почти идентичны, за исключением того, что у них разный номер дела. Я хотел бы настроить Outlook так, чтобы он просто спрашивал у меня номер дела, заполнял его в соответствующем месте в тексте и теме письма, а затем отправлял его заранее заданному списку получателей (это статический список людей).

Я думаю, что это можно сделать с помощью комбинации форм и шаблонов, но я не уверен, как именно.

решение1

Возможное решение VBA

Sub Boilerplate_CaseNumber()

Dim objMail As MailItem
Dim allRecipients As Recipients

Dim uPrompt As String
Dim uCaseNum As String

Set objMail = Application.CreateItem(olMailItem)
Set allRecipients = objMail.Recipients

allRecipients.Add "Your distribution list name inside the quotes"
allRecipients.ResolveAll

uPrompt = "What is the case number?"
uCaseNum = InputBox(prompt:=uPrompt, Title:="Case number")

objMail.Subject = "Here is the Case Number: " & uCaseNum
objMail.Body = "Hello," & vbCrLf & vbCrLf & _
   "The case number is: " & uCaseNum & "." & vbCrLf & vbCrLf & _
   "Yours," & vbCrLf & vbCrLf & _
   "Mykroft"

SendKeys "^{END}"

objMail.Display

Set objMail = Nothing
Set allRecipients = Nothing

End Sub


Sub Boilerplate_CaseNumber_WordEditor()

Dim objMail As MailItem
Dim allRecipients As Recipients

Dim uPrompt As String
Dim uCaseNum As String

Dim objDoc
Dim objSel

Set objMail = Application.CreateItem(olMailItem)
Set allRecipients = objMail.Recipients

allRecipients.Add "Your distribution list name inside the quotes"
allRecipients.ResolveAll

uPrompt = "What is the case number?"
uCaseNum = InputBox(prompt:=uPrompt, Title:="Case number")

objMail.Subject = "Here is the Case Number: " & uCaseNum
objMail.Display

Set objDoc = Application.ActiveInspector.WordEditor
Set objSel = objDoc.Windows(1).selection
objSel.TypeText Text:="Hello," & vbCrLf & vbCrLf & _
   "The case number is: " & uCaseNum & "." & vbCrLf & vbCrLf & _
   "Yours," & vbCrLf & vbCrLf & _
   "Mykroft"

Set objDoc = Nothing
Set objSel = Nothing
Set objMail = Nothing
Set allRecipients = Nothing

End Sub

Справка по редактору и кнопкам -http://www.slipstick.com/developer/how-to-use-outlooks-vba-editor/

Уровень безопасности макросов следует установить на средний.

Кнопка помощи -http://www.howto-outlook.com/howto/macrobutton.htm

Связанный контент