☰

Сжатие нескольких файлов в несколько архивов?

tag-icon • tag-icon compression archiving winrar
Сжатие нескольких файлов в несколько архивов?

У меня есть папка, полная pdf-файлов, и мне надоело архивировать каждый файл отдельно. Я не хочу помещать их все в один архив.

Разве нет командной строки, которую я мог бы использовать, чтобы Winrar сжал файл наилучшим способом, удалил файл после создания .rar, а затем сделал то же самое для следующего файла?

решение1

Да, в папке установки WinRAR есть исполняемый файл rar.exe. Запуск его без параметров показывает полную справку по его использованию. Например, вы можете задать наилучший уровень сжатия с помощью ключа -m5.

Как уже было сказано, пакетный/оболочечный скрипт — хороший способ сделать это, но вам может показаться интересным следующий проект с похожими целями:http://code.google.com/p/autorar/.

решение2

Это скрипт, который я написал для сжатия каждого файла отдельно архиватором rar (формат winrar5). Чтобы сжать все файлы *.pdf в папке по отдельности, вы должны поместить этот скрипт в файл .bat, а затем запустить его. Сначала вы указываете начальный (корневой) каталог, где находятся ваши файлы, затем вы можете указать расширения для поиска и сжатия в этом каталоге (рекурсивный поиск, вход в подкаталоги корневого каталога)

@echo off

REM -m5 max compression    
REM -md64m dictionary size 64m
REM -s solid
REM -ma5 rar5 format (rar4 - ma4)
REM -y yes to all
REM -t test after packing (if test NOT ok, then files will not be deleted if the -df/-dr specified)
REM -df delete files after successful archivation
REM -ep1 exclude base folder of file from archive
:: %%~nZ - file name extracted from var Z
:: %%~fZ - full path of file+ext from var Z
:: %%~dpZ - disk+path
:: setlocal - use local environment vars
setlocal

:step1
    echo Enter start path where files a located
    set /p rarpath=
    echo.
    :: remove doublequotes from path
    set rarpath=%rarpath:"=%

:check dir exist
    if not exist "%rarpath%" echo   "!!!  [%rarpath%] doesn't exist, please enter correct path  !!!"
    if not exist "%rarpath%" echo.
    if not exist "%rarpath%" goto step1
:::::
:::::
    echo.
    echo Enter which extensions to compress (like *.mp4;*.wmv)
    set /p exten=
    echo.
:::::
:::::
    echo.
    echo Final command: 
    echo for /R "%rarpath%" %%Z in (%exten%) do "%programfiles%\WinRAR\rar.exe" a -ma5 -m5 -s -md64m -t -y -ep1 -df "%%~nZ.rar" "%%~fZ"
    echo.
:::::
:::::
    echo.
    echo Continue? [y/n]
    set /p go=
    if /i %go%==Y goto ok
    if /i %go%==N goto exit

:ok
:: CD to each file's directory, compress file, log output (codepage 866)
set rartime=%time:~0,8%
set rartime=%rartime::=_%
set rartime=%rartime: =%
set rarlog=rar_log_%date%_%rartime%.txt
:: For directories located in current directory
:: for /d %D in (*) do "%programfiles%\winrar\rar.exe" a -ma5 -m5 -s -md64m -t -y -ep1 -df "%D.rar" "%D"

    for /R "%rarpath%" %%Z in (%exten%) do (
        cd /d %%~dpZ
        "%programfiles%\WinRAR\rar.exe" a -ma5 -m5 -s -md64m -t -y -ep1 -df "%%~nZ.rar" "%%~fZ" >> c:\%rarlog% 2>&1
        type c:\%rarlog%
        echo. >> c:\%rarlog%
        echo ----------------------------------------------------------------------------- >> c:\%rarlog%
        echo. >> c:\%rarlog%
    )
    echo.
    echo.
    echo        !!! All Done !!!
    pause
    goto :EOF
    ::EXIT /B 0

:exit
    echo Program terminated
    pause
    goto :EOF

Связанный контент