☰

Как получить Magnet-ссылки с помощью Deluge и возможно ли это вообще?

tag-icon • tag-icon deluge
Как получить Magnet-ссылки с помощью Deluge и возможно ли это вообще?

Они говорят, что это больше не совместимо? Почему кнопка с решеткой информации неактивна?

Кто-нибудь знает, как получить Magnet-ссылки с помощью Deluge Web UI Client?

Кстати, моя версия клиента Deluge — 1.3.5.

решение1

В соответствии сAskUbuntu, поддержка magnet в WebUI была добавлена ​​в 1.3.4 еще в мае. Вы уверены, что у вас последняя версия?

решение2

Я нажимаю правой кнопкой мыши на magnet-ссылке и выбираю «Копировать адрес ссылки» или что-то подобное, а затем копирую эту ссылку в Deluge в «Добавить торрент».

решение3

Для Mac, пользователь GitHubЛорд-КаминанаписалПотоп-Магнит-Обработчик, обходной путь AppleScript. Устанавливается в папку «Программы» и запускается один раз, чтобы связать себя со magnet:ссылками, эти URL-адреса должны автоматически открываться в Deluge.

on quit
    try
        tell application "System Events" to tell process "Deluge"
            activate
            set frontmost to true
            windows where title contains "Add Torrents"
            if result is not {} then perform action "AXRaise" of item 1 of result
        end tell
    end try
end quit

on open location this_URL
    try
        tell application "Finder" to set delugePath to POSIX path of (application file id "org.deluge" as string)
        set appExists to true
    on error
        set appExists to false
        display alert "Deluge.app must be installed in order to use this plug-in." as critical
        return
    end try
    set delugeArgument to quoted form of this_URL
    try
        tell application "Deluge" to activate
    end try
    do shell script (quoted form of (delugePath & "/Contents/MacOS/Deluge") & " add " & delugeArgument & "; return;")
    quit
end open location
tell application "Finder" to set thisPath to (POSIX path of (application file id "org.deluge.MagnetURIHandler" as string))
log thisPath
set lsToolRead to do shell script (quoted form of (thisPath & "/Contents/Resources/lstool") & " read url magnet")
if (lsToolRead contains "Magnet Handler.app") then
    display dialog "Magnet Handler is already the default application to handle magnet URIs" buttons {"OK"} with title "Notification" with icon POSIX file (thisPath & "/Contents/Resources/deluge_magnet.icns")
else
    try
        set dialogResult to display dialog "Magnet Handler has not been configured to handle magnet URIs.

Would you like to do this now?" buttons {"Yes", "No"} default button "Yes" cancel button "No" with title "Notification" with icon POSIX file (thisPath & "/Contents/Resources/deluge_magnet.icns")
    on error number -128
    end try
    try
        if button returned of dialogResult is "Yes" then
            do shell script (quoted form of (thisPath & "/Contents/Resources/lstool") & " write url magnet org.deluge.MagnetURIHandler")
            display dialog "Magnet Handler has now been configured as the default application to handle magnet URIs" buttons {"OK"} with title "Notification" with icon POSIX file (thisPath & "/Contents/Resources/deluge_magnet.icns")

        end if
    end try
end if
quit

Связанный контент