☰

Поиск уникальных значений в 3 столбцах

tag-icon • tag-icon microsoft-excel-2010
Поиск уникальных значений в 3 столбцах

У меня есть 3 столбца в Excel. Я хочу найти уникальные значения в столбцах A, B и C.

Так:

  1. Просматривая столбец A, я хочу найти уникальные значения, которых нет в B или C.
  2. просматривая столбец B, я хочу найти уникальные значения, которых нет в столбцах A или C.
  3. Просматривая столбец C, я хочу найти уникальные значения, которых нет в столбце A или B.

Вот что я написал в колонке А

=IF(OR(MATCH(A3,$B$3:$B$631,0),(MATCH(A3,$C$3:$C$408,0))),"Match",A3)

Вот что я написал в колонке B

=IF(OR(MATCH(B3,$A$3:$A$857,0),(MATCH(B3,$C$3:$C$408,0))),"Match",B3)

Вот что я написал в колонке C

=(IF(OR(MATCH(C3,$A$3:$A$857,0),(MATCH(C3,$B$3:$B$631,0))),"Match",C3)

Это дает мне дублирующиеся значения в трех столбцах, которые мне нужны, чтобы они были уникальными. Может быть, я просто все усложняю. Есть идеи, как это сделать?

Пример таблицы:

A   B   C
1   2   2
2   3   3
3   7   7
4   8   11
5   9   12
6   10  13

В этом случае мне нужен уникальный номер в каждом столбце. Так, для столбца A уникальные значения, которых нет в столбцах B или C, равны = 1,4,5,6. В столбце B уникальные значения, которых нет в A или C, равны =8,9, 10. В столбце C уникальные значения, которых нет в B или C, равны = 11, 12, 13. Я хочу создать формулу в столбцах D, E, F для этих трех формул.

АБВ 1 2 2 2 3 3 3 7 7 4 8 11 5 9 12 6 10 13

В этом случае мне нужен уникальный номер в каждом столбце. Так, для столбца A уникальные значения, которых нет в столбцах B или C, равны = 1,4,5,6. В столбце B уникальные значения, которых нет в A или C, равны =8,9, 10. В столбце C уникальные значения, которых нет в B или C, равны = 11, 12, 13. Я хочу создать формулу в столбце c D, E, F для этих трех формул.

решение1

Вы можете использовать формулу массива †, например, в D1:

=IFERROR(INDEX($A$1:$A$6,SMALL(IF(ISERROR(MATCH($A$1:$A$6,$B$1:$B$6,0))*ISERROR(MATCH($A$1:$A$6,$C$1:$C$6,0)),ROW($A$1:$A$6)),ROW())),"")

Формулы в других столбцах аналогичны:

Э1:

=IFERROR(INDEX($B$1:$B$6,SMALL(IF(ISERROR(MATCH($B$1:$B$6,$A$1:$A$6,0))*ISERROR(MATCH($B$1:$B$6,$C$1:$C$6,0)),ROW($B$1:$B$6)),ROW())),"")

Ф1:

=IFERROR(INDEX($C$1:$C$6,SMALL(IF(ISERROR(MATCH($C$1:$C$6,$A$1:$A$6,0))*ISERROR(MATCH($C$1:$C$6,$B$1:$B$6,0)),ROW($C$1:$C$6)),ROW())),"")

А из вашего примера таблицы я получаю следующее:

введите описание изображения здесь

Если ваша формула начинается не с первой строки, а с другой, ее придется немного изменить, поскольку она использует ROW()значение, зависящее от строки, в которой она размещена.

† Примечание: чтобы использовать формулу, необходимо нажать и удерживать Ctrl+, Shiftа затем нажать Enterпосле ее вставки.

Связанный контент