Как сделать подсказку с помощью msgbox VBA

Question

Как сделать подсказку с помощью msgbox в VBA, когда строки Excel меняются на другие буквы.

Например, если в строке 1 у меня AAB, а в строке 2 — BBA, мне нужно поле подсказки после строки 1.

Answer 1

Попробуйте этот небольшой макрос, он настроен на столбецС

Sub DataCheck()
    Dim MyCol As String, rCheck As Range, r As Range
    MyCol = "C"
    Set rCheck = Intersect(ActiveSheet.UsedRange, Range(MyCol & ":" & MyCol))

    For Each r In rCheck
    If r.Row = 1 Then
    Else
        If r.Text <> r.Offset(-1, 0).Text Then
            r.Select
            MsgBox "Data changed in row #" & r.Row
        End If
    End If
    Next r
End Sub

Например:

ПРАВКА №1:

Эта версия кода обнаружит изменения в столбцеСи вставьте между ними строку-«разделитель»:

Sub DataCheck2()
    Dim MyCol As String, rCheck As Range, r As Range
    Dim rInsert As Range
    MyCol = "C"
    Set rCheck = Intersect(ActiveSheet.UsedRange, Range(MyCol & ":" & MyCol))
    Set rInsert = Nothing

    For Each r In rCheck
        If r.Row = 1 Then
        Else
            If r.Text <> r.Offset(-1, 0).Text Then
                If rInsert Is Nothing Then
                    Set rInsert = r
                Else
                    Set rInsert = Union(rInsert, r)
                End If
            End If
        End If
    Next r

    If rInsert Is Nothing Then
    Else
        rInsert.EntireRow.Insert
    End If

End Sub

До:

и после: