☰

Пакетный файл для запуска программ от имени администратора - ошибка 740

tag-icon • tag-icon windows-7 command-line batch-file
Пакетный файл для запуска программ от имени администратора - ошибка 740

Я работаю над небольшим пакетным скриптом, который повышает права администратора для основных программ Windows.

Все функции работают нормально, но я столкнулся с проблемой при попытке запустить «regedit.exe».

Когда в скрипте выбран вариант 3 и он должен запустить regedit от имени администратора, я получаю ошибку:

740: Запрошенная операция требует повышения уровня.

Вот сценарий:

echo off
cls
echo.
echo Start as admin:
echo /----------------\
echo # 1. CMD         #
echo # 2. Task Manager#
echo # 3. Regedit     #
echo # 0. Exit        #
echo \----------------/
echo.

set /p run=

if %run%==1 (
set run="cmd"
)

if %run%==2 (
set run="taskmgr"
)

if %run%==3 (
set run="regedit"
)

if %run%==0 (
exit
)

runas /savecred /user:admin %run%

Есть ли способ обойти эту проблему?

Я хотел бы сделать так, чтобы это работало без установки сторонних программ, изменения реестра или отключения UAC.

решение1

Это можно сделать, запустив новую командную строку CMD с помощью RunAs, которой вы указываете запустить свою команду.

Чтобы сделать это в вашем пакете, измените последнюю строку на:

runas /savecred /user:admin "cmd /c %run%"

решение2

Add this to the top of your Batch file and at the end just put %run% instead of (runas /savecred /user:admin %run%)


@echo off

:: BatchGotAdmin
:-------------------------------------
REM  --> Check for permissions
>nul 2>&1 "%SYSTEMROOT%\system32\cacls.exe" "%SYSTEMROOT%\system32\config\system"

REM --> If error flag set, we do not have admin.
if '%errorlevel%' NEQ '0' (
    echo Requesting administrative privileges...
    goto UACPrompt
) else ( goto gotAdmin )

:UACPrompt
    echo Set UAC = CreateObject^("Shell.Application"^) > "%temp%\getadmin.vbs"
    set params = %*:"=""
    echo UAC.ShellExecute "cmd.exe", "/c %~s0 %params%", "", "runas", 1 >> "%temp%\getadmin.vbs"

    "%temp%\getadmin.vbs"
    del "%temp%\getadmin.vbs"
    exit /B

:gotAdmin
    pushd "%CD%"
    CD /D "%~dp0"
:--------------------------------------

решение3

Возможноэтотможет помочь, или, может быть, запуск всего пакета от имени администратора может помочь, создав другой пакетный скрипт, содержащий:

runas /user:admin C:\Path_to_your_batch_file\name.bat

решение4

  1. Щелкните правой кнопкой мыши C:\Windows\regedit.exe и выберите «Свойства».
  2. На вкладке «Совместимость» выберите «Запускать эту программу от имени администратора».

Связанный контент