пакетный файл для получения частичной последней измененной строки в переменную

Question

WMIC path Win32_Directory WHERE name="W:\\foldername" get lastmodified

возвращает что-то вроде этого

Последнее изменение
20140612095434.758265-240

Я хотел бы поместить это в пакетный файл, чтобы присвоить выделенную жирным шрифтом часть этой строки переменной, чтобы я мог использовать ее позже в пакетном файле.

Любая помощь приветствуется!

Это мой пакетный файл для справки

@echo off
@cls
net use W: \\file\home\ex-employees
cd W:
W:

REM Get user ID
set /p id="Enter ID of user to Archive: "

REM Get last modified code goes here assigned to "LM" variable
REM
REM WMIC path Win32_Directory WHERE name='W:\\rsink' get lastmodified

REM Join Variables
call set filename=%%%id%%LM%%%

call zipjs.bat zipItem -source %id% -destination .\%filename%.zip -keep yes -force no

rmdir /S /Q %id%

Echo All Done!
@pause

Answer 1

Я хотел бы поместить это в пакетный файл, чтобы назначить выделенную жирным шрифтом часть этой строки переменной.

WMIC path Win32_Directory WHERE name="W:\\foldername" get lastmodified

возвращает что-то вроде этого

Последнее изменение

20140612095434.758265-240

Для этого можно использовать for /fцикл. Вот небольшой пример.

ПолучитьДатаПоследнегоИзменения.cmd:

@echo off 
rem GetLastModifedDate.cmd
setlocal enabledelayedexpansion
rem skip header line
rem use findstr to remove blank lines
for /f "skip=1 tokens=*" %%d in ('WMIC path Win32_Directory WHERE name^="f:\\test" get lastmodified ^| findstr /r /v "^$"') do (
  set LM=%%d
  rem required part is alway 8 chars yyyymmdd so strip first 8 chars
  set LM=!LM:~0,8!
  )
echo %LM%
endlocal

Ваш пакетный файл с необходимыми изменениями:

@echo off
@cls
setlocal enabledelayedexpansion 
net use W: \\file\home\ex-employees
cd W:
W:

REM Get user ID
set /p id="Enter ID of user to Archive: "

REM Get last modified code goes here assigned to "LM" variable
rem skip header line
rem use findstr to remive blank lines
for /f "skip=1 tokens=*" %%d in ('WMIC path Win32_Directory WHERE name^="W:\\rsink" get lastmodified ^| findstr /r /v "^$"') do (
  set LM=%%d
  rem required part is alway 8 chars yyyymmdd so strip first 8 chars
  set LM=!LM:~0,8!
  )

REM Join Variables
call set filename=%%%id%%LM%%%

call zipjs.bat zipItem -source %id% -destination .\%filename%.zip -keep yes -force no

rmdir /S /Q %id%

Echo All Done!
@pause

---

Дальнейшее чтение

• Индекс AZ командной строки Windows CMD- Отличный справочник по всем вопросам, связанным с командной строкой Windows.
• включеноотложенное расширение- Отложенное расширение приведет к тому, что переменные будут расширяться во время выполнения, а не во время анализа.
• для /ф- Циклическая команда по результатам другой команды.
• переменные- Извлечь часть переменной (подстроку).
• wmic- Команда инструментария управления Windows.