☰

FFmpeg в пакетном режиме FOR Loop для продолжительности MP3

tag-icon • tag-icon windows command-line ffmpeg batch mp3
FFmpeg в пакетном режиме FOR Loop для продолжительности MP3

У меня есть список MP3. Я хотел бы видеть на экране и в файле по одному MP3 на строку с указанием его продолжительности. Вот пакетный файл, который я использую:

@echo off

cls
if exist MP3Duration.txt del MP3Duration.txt

for %%i in (*.mp3) do (
  echo %%i
  echo %%i >> MP3Duration.txt
  ffmpeg -i "%%i" | find "Duration" >> MP3Duration.txt
)

Это имеет несколько проблем: выходной файл содержит имена файлов, но не содержит длительностей, а на экране отображается много текста ffmpeg и для каждого файла ошибка: «Необходимо указать хотя бы один выходной файл».

решение1

ffmpegВывод консоли предназначен только для информационных целей и не должен анализироваться скриптами. ffprobeВместо этого используйте:

ffprobe -loglevel error -select_streams a -show_entries stream=duration -sexagesimal -of default=noprint_wrappers=1:nokey=1 "%%i" | TEE.BAT -a MP3Duration.txt

Также смДокументация FFprobeиFFmpeg Wiki: Советы по FFprobe.

решение2

Чтобы получить информацию о СМИ в следующем формате:

1.mp3|00:33:11
2.mp3|00:34:28
3.mp4|00:04:18
4.mp4|00:02:18

Используйте следующий код:

@echo off
>output.txt (
    for %%F in (*.mp3 *.mp4) do (
        for /f "tokens=2-5 delims=:., " %%a in (
            'ffmpeg -i "%%F" 2^>^&1 ^| find "Duration:"'
        ) do (
            set /p =%%~nxF^|<nul
            setlocal enableDelayedExpansion
            set /a "duration=1%%a*3600 + 1%%b*60 + 1%%c - 366100"
            REM echo !duration!.%%d seconds
            echo %%a:%%b:%%c
            endlocal
        )
    )
)
pause

Результаты будут записаны в файл output.txt, который можно открыть в программах для работы с электронными таблицами, например Excel, для дальнейшей обработки.

решение3

rem this assumes ffmpeg is in c:\ffmpeg


if exist filelist.txt ( del /F filelist.txt )
if exist list.txt ( del /F list.txt )
copy nul list.txt >nul

rem change exts as needed for your audio files

    if exist *.mkv ( dir/b *.mkv >>list.txt )   
    if exist *.fl? ( dir/b *.fl? >>list.txt )   
    if exist *.avi ( dir/b *.avi >>list.txt )   
    if exist *.mp4 ( dir/b *.mp4 >>list.txt )   
    if exist *.mov ( dir/b *.mov >>list.txt )   
    if exist *.swf ( dir/b *.swf >>list.txt )

sort <list.txt >filelist.txt   


for /F "delims=;" %%F in ( filelist.txt ) do (
        for %%F in (^"%%F^") do (
            for /f "tokens=2-5 delims=:., " %%a in (
                'c:\ffmpeg\ffmpeg -i "%%F" 2^>^&1 ^| find "Duration:"'
            ) do (
                set /a full=%%a * 60 * 60 + %%b * 60 + %%c
            )
        )
        echo Length of %%F is %%a:%%b:%%c or !full! Seconds
)

Связанный контент