☰

Пакетный скрипт для вывода списка всех файлов на диске

tag-icon • tag-icon windows command-line batch
Пакетный скрипт для вывода списка всех файлов на диске

Я хотел бы создать небольшой пакетный файл, который перечислит меня всех на одном файле на диске. Команда такая:

TREE L: / F / A> List.txt

Но я бы хотел, чтобы пользователь вводил букву диска для обработки, а результат помещался в файл с именем и текущей датой. Пример:

C:\> makelist.bat
Please, insert the drive letter: L
Done!

Результат необходимо ввести в файл с именем, например, List_2017-03-13.txtи переместить на Рабочий стол.

Какие команды следует использовать для создания скрипта?

решение1

В следующем пакете используется wmic для

  • получить независимую от локали/пользовательских настроек дату
  • получить список доступных букв дисков
  • и возможность выбрать букву
:: makelist.bat
@Echo off&SetLocal EnableExtensions EnableDelayedExpansion
set Started=%date% %time%
:: get locale/user-settings independent date
for /f "delims=." %%A in (
  'wmic os get LocalDateTime^|findstr ^^[0-9]'
) do Set "DT=%%A"
Set MyDate=%DT:~0,4%-%DT:~4,2%-%DT:~6,2%

:: gather available drives
Set "Drives="
FOr /f "delims=:" %%A in (
  'Wmic logicaldisk get name^|findstr "^[A-Z]:"'
) DO Set "Drives=!Drives!%%A"

:: choose drive letter
Choice /C %Drives% /M "Select drive letter for tree"
Set /A "Inp=%Errorlevel%,Pnt=Inp-1"
IF %Inp% equ 0   Echo aborted & pause & exit /B 1
If %Inp% equ 255 Echo aborted & pause & exit /B 1
Set "Drive=!Drives:~%Pnt%,1!"

:: do the tree 
Echo %Started% Tree started
Echo Tree %Drive%:\ /F /A  "%UserProfile%\Desktop\Tree_%Drive%_%MyDate%.txt"
     Tree %Drive%:\ /F /A >"%UserProfile%\Desktop\Tree_%Drive%_%MyDate%.txt"
Echo %date% %time% done
timeout -1

Пример диалога:

Select drive letter for tree [C,D,E,G,H,K,M,N,P,Q,R,T,U,V,W,X,Z]?H
2017-03-13 14:17:05,45 Tree started
Tree H:\ /F /A "C:\Users\UserName\Desktop\Tree_H_2017-03-13.txt"
2017-03-13 14:17:13,70 done

Drücken Sie eine beliebige Taste, um den Vorgang fortzusetzen...

решение2

tree2txt.bat:

@tree %1 / F / A > Tree_%1_%date.TxT

Использование: tree2txt X:

Результат: дерево диска X:\ в файл с именем Tree_X_20170313.TxT

Обратите внимание, что формат вывода даты зависит от ваших локальных настроек формата даты (гггг-мм-дд и других форматов).

Связанный контент