☰

Пакетный экспорт выбранных видео с помощью QuickTime Player 7, используя определенные настройки экспорта?

tag-icon • tag-icon macos batch applescript automator quicktime
Пакетный экспорт выбранных видео с помощью QuickTime Player 7, используя определенные настройки экспорта?

Как я могу использовать AppleScript или Automator для пакетного экспорта видеофайлов, которые я выбрал в Finder, ноНЕТс помощью сервиса «Кодирование выбранных видеофайлов», в котором на выбор предлагается всего 4 формата?

По сути, мне нужно экспортировать видео, используя «Последние настройки», выбранные при последнем экспорте видео из QuickTime 7, или иметь возможность указать настройки с помощью диалогового окна экспорта в QuickTime 7, чтобы выбрать конкретное форматирование, необходимое для выбранных мной видео.

Иногда мне нужно, чтобы кодек был "Apple ProRes 422 LT", а иногда мне нужно использовать обычный "Apple ProRes 422". Мне также нужно убедиться, что частота кадров установлена ​​на 30 независимо от частоты кадров исходного файла, а размеры будут либо 1280x720, либо 1920x1080.

Наконец, мне также нужно будет задать разные параметры кодирования звука для разных видео.

Надеюсь, кто-то знает, как это сделать. Я копался здесь и в Google, но так и не смог разобраться. Кажется, большая часть информации, которую я нахожу в сети, просто рассказывает людям, как использовать тот же метод, который использует службу «Encode Selected Video Files».

решение1

Эврика! Я нашел в сети рабочий процесс Automator, который действительно работает. Мне просто пришлось его модифицировать, чтобы в качестве входных данных использовались файлы фильмов вместо изображений. Он использует «Последние настройки» в QuickTime 7, поэтому мне нужно просто вручную экспортировать первое видео, чтобы правильно ввести настройки, а остальное я могу просто выбрать и обработать в пакетном режиме. Ура!

Оригинальная страница с информацией и файлом рабочего процесса, которую я нашел, находится здесь: http://ptrbrtz.net/batch-convert-animated-gifs-to-videos-using-applescript-automator-quicktime-7-on-os-x/

Я добавлю сюда скрипт на случай, если страница, на которую я ссылаюсь, когда-нибудь исчезнет. Его просто нужно добавить в Automator как службу, с файлами фильмов из Finder в качестве входных данных.

изображение, показывающее, как добавить службу в Automator

А вот AppleScript для добавления в сервис. Я только что сохранил сервис как "Export_mov_via_QuickTime7.workflow".

on run {inputFiles}
    if inputFiles is equal to {} then
        set inputFiles to (choose file with prompt "Select the file(s) to convert:" with multiple selections allowed without invisibles)
    end if
    open inputFiles
end run

on open droppedItems
    tell application "Finder" to set inputFolder to (container of first item of droppedItems) as Unicode text
    set outputFolder to (choose folder with prompt "Select output folder:" default location (inputFolder as alias)) as Unicode text

    display dialog "Most recent QuickTime 7 export settings will be used.
Existing files will be overwritten/moved to trash!
Beware of evil QT7 Gamma shift!"

    tell application "QuickTime Player 7"
        activate
        close every window
    end tell

    repeat with currentItem in droppedItems
        tell application "Finder" to set fileName to name of currentItem as Unicode text

        tell application "QuickTime Player 7"
            open currentItem
            tell front document to set frameCount to count of frames of first track
        end tell

        set outputFileName to (outputFolder & fileName & ".mov")

        tell application "Finder"
            if exists file outputFileName then
                delete file outputFileName
            end if
        end tell

        tell application "QuickTime Player 7"
            if frameCount is greater than 1 then
                with timeout of 86400 seconds -- 24 hours
                    export front document to outputFileName as QuickTime movie using most recent settings
                end timeout
            end if
            close front document
        end tell
    end repeat

    quit application "QuickTime Player 7"
end open

Теперь, когда вам понадобится выполнить пакетный экспорт видео с помощью QuickTime Player 7 Pro с любыми выбранными вами настройками, вам просто нужно выбрать все остальные видео, которые вы хотите экспортировать, выбрать службу в меню Finder->Службы и насладиться приятным перерывом на кофе, пока все ваши видео конвертируются! =D

Связанный контент