☰

Сравните два столбца в разных рабочих книгах.

tag-icon • tag-icon microsoft-excel microsoft-excel-2010 vba
Сравните два столбца в разных рабочих книгах.

Я был бы признателен, если бы мне помогли с проблемой, связанной с созданием макроса vba. У меня есть две рабочие книги, и я хочу сравнить столбец "N" в рабочей книге 1 со столбцом "F" в рабочей книге 2. Затем, если есть совпадение, перейти к следующей ячейке вниз, если совпадений не найдено, я хочу скопировать следующую ячейку после столбца "F" в рабочей книге 2. Рабочая книга 2 не будет иметь того же имени, когда я получу ее каждое утро, но имя рабочей книги всегда начинается с "Копия", поэтому я создал код ниже, чтобы выбрать ее, используя частичное имя.

For Each ws In ActiveWorkbook.Worksheets
    If ws.Name Like "Copy of*" Then
        ws.Select
        Exit For
    End If
Next ws

Даже если мне укажут правильное направление, это будет здорово.

решение1

Это объяснение не очень понятно

...если есть совпадение, перейти к следующей ячейке ниже, если совпадений не найдено, я хочу скопировать следующую ячейку после столбца «F» в рабочей книге 2...

но попробуйте что-то вроде этого и измените это соответствующим образом

Option Explicit

Public Sub CompareWorkBooks()
    Dim ws1 As Worksheet, ws2 As Worksheet

    Set ws1 = ThisWorkbook.Worksheets("Sheet1")
    Set ws2 = GetWSCopy("Copy of*")

    If Not ws2 Is Nothing Then

        Dim r As Long, cel As Range, found As Variant, ws2lr As Long

        optimizeXL True
        For r = ws1.UsedRange.Rows.Count To 1 Step -1
            Set cel = ws1.Cells(r, ws1.Columns("N").Column)
            If Len(cel.Value2) > 0 Then
                found = Application.Match(cel.Value2, ws2.UsedRange.Columns("F"), 0)

                If Not IsError(found) Then  'a match was found so move next cell down
                    cel.Offset(1).EntireRow.Insert xlDown
                Else    'match not found so copy row from ws1 to first empty row of ws2
                    ws2lr = ws2.UsedRange.Rows.Count + 1
                    ws1.UsedRange.Rows(cel.Row).EntireRow.Copy ws2.Cells(ws2lr, 1)
                End If
            End If
        Next
        optimizeXL False
    End If
End Sub

Private Function GetWSCopy(ByVal wsName As String) As Worksheet
    Dim ws As Worksheet
    For Each ws In ThisWorkbook.Worksheets
        If ws.Name Like wsName Then
            Set GetWSCopy = ws
            Exit Function
        End If
    Next
End Function

Public Sub optimizeXL(Optional ByVal settingsOff As Boolean = True)
    With Application
        .ScreenUpdating = Not settingsOff
        .Calculation = IIf(settingsOff, xlCalculationManual, xlCalculationAutomatic)
        .EnableEvents = Not settingsOff
    End With
End Sub

Кроме того, вы ссылаетесь на 2 рабочие книги (файлы),
но ваш код ссылается на рабочие листы (вкладки в одной и той же рабочей книге)

Связанный контент