☰

Пакетный файл или утилита для проверки Wi-Fi Watchdog?

tag-icon • tag-icon windows-7 networking wireless-networking batch monitoring
Пакетный файл или утилита для проверки Wi-Fi Watchdog?

Я использую старую систему Windows 7 по Wi-Fi, к которой я подключаюсь удаленно для мониторинга.

Проблема в том, что Wi-Fi непредсказуем (из-за странных проблем с маршрутизатором), а мне нужно, чтобы эта система была в сети в любое время дня. Как ни странно, когда Wi-Fi отключается, он не имеет тенденцию автоматически переподключаться, хотя он все еще доступен и Windows настроен на переподключение к нему.

Я нашел похожий вопрос с ответом здесь, но он касался проводной сети и, к сожалению, решение не работает для моей системы.

Это пакетный файл, как создано ниже. Я запустил его, отключил маршрутизатор Wi-Fi, что остановило пинги, но он не завершил оператор if для сброса интерфейса. Окно команд просто показывает, что пинг истек, и продолжает повторять это, пока соединение не будет восстановлено. Файл журнала не регистрирует ошибку, поэтому он никогда не добирается до части ошибки оператора if. Я изменил исходную переменную "Interface" с "Local Area Connection" на "Wireless Network Connection"

Может ли кто-нибудь устранить эту неполадку или предложить альтернативный вариант для автоматического сброса адаптера при падении сети, поскольку это, похоже, исправляет проблему. Нужно ли мне добавлять "Беспроводное сетевое соединение (%SSID%)" в качестве интерфейса?

Спасибо!

Panterateama

@echo off
set INTERFACE="Local Area Connection"
set TIMEOUT=3600
set IP=8.8.8.8
set LOG="watchdog.log"

echo %DATE% %TIME%: Watchdog started >> %LOG%

:loop
rem First check the interface for an hour by pinging the Google DNS
rem and resetting the networking interface if it should fail.
ping -n %TIMEOUT% -w 1000 -l 0 %IP%
if %errorlevel% NEQ 1 goto :loop
echo %DATE% %TIME%: Connection failed. Restarting interface.. >> %LOG%
netsh interface set interface %INTERFACE% disable
netsh interface set interface %INTERFACE% enable

rem Give it another shot but restart the whole computer if it the 
communication should still fail
ping -n %TIMEOUT% -w 1000 -l 0 %IP%
if %errorlevel% NEQ 1 goto :loop
echo %DATE% %TIME%: Still no connection. Restarting computer.. >> %LOG%
shutdown /r /c "Internet wathchdog"

echo %DATE% %TIME%: Waiting for system to shut down >> %LOG%
choice /T %TIMEOUT% /D Y /N > NUL
echo %DATE% %TIME%: Gave up on the shut down attempt. Trying again.. >> 
%LOG%
goto :loop

решение1

Измените TIMEOUT на 30. Это заставит его выполнить сброс, если соединение было отключено в течение 30 секунд. В противном случае оно должно быть отключено в течение 3600 секунд (1 час).

Также вам не следует использовать 8.8.8.8 для этой цели. Вместо этого вам следует использовать IP-адрес вашего шлюза, найденный с помощью ipconfig. Если вы используете внешний IP, такой как 8.8.8.8, ваш компьютер сбросит соединение и даже продолжит перезагружать компьютер, если что-то вроде вашего интернета просто отключится.

Используя внутренний IP-адрес, например адрес шлюза, он будет сбрасываться или перезагружаться только тогда, когда соединение Wi-Fi фактически прервется.

Также вы можете запустить это как запланированную задачу для запуска с наивысшими привилегиями, как nt authority\systemпри запуске компьютера. Но я бы изменил тайм-аут на что-то немного большее, например, 300 секунд, потому что скрипт может запуститься до того, как ваш сетевой стек станет полностью работоспособным.

EDIT: Как указано в комментариях, скрипт, размещенный в вопросе, просто не работает. Проблема с исходным скриптом в том, что команда ping может вернуть "Ответ от xxx.xxx.xxx.xxx: целевой хост недоступен", что приводит к "успешному" уровню ошибки.

Ниже приведен обновленный скрипт, который работает и изменяет логику так, чтобы он более эффективно обнаруживал отключенное соединение. Я также удалил часть, которая перезагружала бы компьютер — я считаю, что это ненужно и потенциально проблематично. Обратите внимание, что на экране НЕ будет вывода от этой команды, когда она выполняется. Убедитесь, что с помощью команды получено правильное имя сетевого интерфейса netsh interface show interface.

@echo off
REM Modified by Appleoddity - 10/11/2017
REM Fixed ping status check; Removed shutdown/reboot ability; Improved logging
REM This script MUST RUN AS ADMIN
REM
REM Obtain network interface name with 'netsh interface show interface'
REM 
REM Change the INTERFACE; THRESHOLD; IP; and LOG variables below.
REM Note: THRESHOLD is not necessarily the number of seconds before reset - but close
REM
setlocal EnableDelayedExpansion
set INTERFACE="Wi-Fi"
set THRESHOLD=30
set IP=10.1.10.1
set LOG="watchdog.log"

echo %DATE% %TIME%: Watchdog started >> %LOG%

SET /A COUNT=0
REM Loop until <THRESHOLD> failed, consecutive pings are counted
:LOOP
ping -n 1 -w 1000 -l 0 %IP% | find /i " bytes=" >NUL 2>&1
if errorlevel 1 (
    set /A COUNT+=1
    echo %DATE% %TIME%: Failed ping detected - Count = !COUNT!. >> %LOG%
) ELSE (
    set /A COUNT=0
    REM Pause
    ping -n 2 -w 1000 -l 0 127.0.0.1 >NUL 2>&1
)
if %COUNT% GEQ %THRESHOLD%  (
    echo %DATE% %TIME%: %THRESHOLD% failed pings exceeded. >> %LOG%
    GOTO RESET
)
GOTO LOOP

REM Reset the network interface
:RESET
echo %DATE% %TIME%: Restarting network interface - %INTERFACE% >> %LOG%
netsh interface set interface "%INTERFACE%" admin=DISABLED >NUL 2>&1
netsh interface set interface "%INTERFACE%" admin=ENABLED >NUL 2>&1
SET /A COUNT=0
GOTO LOOP

решение2

Если вы получаете«Интерфейс с таким именем не зарегистрирован на маршрутизаторе»ошибка, то это означает, что вы не выбрали правильный сетевой адаптер в своем скрипте.

Вы запускаете пакет/команду от имени администратора?

Если вы хотите убедиться, что у вас есть права администратора, вы можете запуститьncpa.cplили

netsh interface show interface

который выдаст вам список адаптеров, а затем напишите что-то вроде этого, основываясь на именах ваших адаптеров:

netsh interface set interface name="Local area connection" admin="disabled"
netsh interface set interface name="Wireless Network Connection" admin="disabled"
netsh interface set interface name="Local area connection" admin="enabled"
netsh interface set interface name="Wireless Network Connection" admin="enabled"

Это сбросит настройки нужного вам адаптера, плюс вы можете использовать &, чтобы соединить их все вместе:

netsh interface set interface name="Local area connection" admin="disabled" & netsh interface set interface name="Local area connection" admin="enabled"

Связанный контент