Копировать уникальные значения из двух столбцов в третий столбец

Question

У меня есть основной список заказов в электронной таблице.

В столбце A перечислены все заказы. В столбце B перечислено подмножество всех заказов. Если бы оба списка были небольшими, я мог бы сделать это вручную, но мне нужно просмотреть сотни записей.

Каков наилучший способ найти значения из столбца A, которых нет в столбце B, и поместить их в столбец C?

Визуально я собираюсь создать столбец C следующим образом:

Column A       Column B       Column C
A1             A3             A1
A2             A5             A2
A3                            A4
A4
A5

Обратите внимание, что я не просто пытаюсь выделить уникальные значения в столбце A, а пытаюсь скопировать эти уникальные значения в новый столбец (C).

Answer 1

Пытаться:

=IFERROR(INDEX($A$1:$A$100,AGGREGATE(15,6,1/(1/(ISNA(MATCH($A$1:$A$100,$B$1:$B$100,0))*ROW($A$1:$A$100)*($A$1:$A$100<>""))),ROWS($1:1))),"")

Answer 2

Это очень просто сделать с помощью «вспомогательной» колонки.Д1входить:

=IF(ISERROR(MATCH(A1,$B$1:$B$5,0)),1,"")

И вД2входить:

=IF(ISERROR(MATCH(A2,$B$1:$B$5,0)),1+MAX($D$1:D1),"")

и копировать вниз. КолонкаДпомечает каждую строку, содержащую полезные данные, уникальным идентификатором. СтолбецДговорит использовать сначала получить данные из строки №1, затем получить данные из строки №2, затем получить данные из строки №4

Затем вС1входить:

=IFERROR(INDEX($A$1:$A$5,MATCH(ROWS($1:1),D:D,0)),"")

и скопируйте вниз:

Answer 3

Я хотел бы предложить вам простую формулу ВПР, которая сравнит столбцы A и B и извлечет уникальные значения в столбце C.

=IF(ISNA(VLOOKUP(A2,$B$2:$B$6,1,FALSE)),A2,"")

Надеюсь, это вам поможет.