☰

Попытка объединить информацию из нескольких строк в одну строку

tag-icon • tag-icon microsoft-excel vba
Попытка объединить информацию из нескольких строк в одну строку

Я полный новичок в написании макросов/VB для Excel, и эта проблема меня действительно затронула.

Вот пример того, что у меня есть

1

И вот на что я надеюсь

2

Как вы видите, я надеюсь объединить индивидуальные оценки и их комментарии для каждого reviewer_id, для каждого appl_id, а также вытащить ОБЩУЮ оценку для каждого appl_id. Иногда для оценок нет комментариев, что, кажется, усложняет задачу. Эта таблица имеет длину около 2 тыс. строк, поэтому делать это вручную не показалось возможным.

решение1

Этот макрос обработает данные согласно вашему примеру. Если у вас больше 3 рецензентов на appl_id, то вам нужно изменить mr. Вы также можете захотеть изменить лист и диапазон, на которые ссылается REF.

Sub marine()

Dim REF As Range
Dim REF2 As Range
Set REF = Sheets("Sheet1").Range("A1") 'location of start of data table set. Set this to the correct reference.

Sheets.Add After:=ActiveSheet
ActiveSheet.Name = "Processed"

Set REF2 = Sheets("Processed").Range("A1")

' max number of reviewers
mr = 3

' set headers
REF2.Value = "appl_id"
For i = 1 To mr
 REF2.Offset(0, (i - 1) * 2 + 1).Value = "score_" & i
 REF2.Offset(0, (i - 1) * 2 + 2).Value = "comment_" & i
Next i
REF2.Offset(0, mr * 2 + 1).Value = "aggregate_score"

i = 1
a = 0
s = 0
Do While (REF.Offset(i, 0).Value <> "")
 appl_id = REF.Offset(i, 0).Value
 If (appl_id <> REF.Offset(i - 1, 0).Value) Then 'new apple_id
   a = a + 1
   s = 0
   REF2.Offset(a, 0).Value = appl_id 'set new apple_id row
 End If
 If (REF.Offset(i, 1).Value = "AGGREGATE") Then
   REF2.Offset(a, mr * 2 + 1).Value = REF.Offset(i, 2).Value 'set aggregate
 Else
   REF2.Offset(a, s + 1).Value = REF.Offset(i, 2).Value 'set score
   REF2.Offset(a, s + 2).Value = REF.Offset(i, 3).Value 'set comment
   s = s + 2
 End If

 i = i + 1
Loop

End Sub

Связанный контент