☰

Макрос/код VBA для вывода списка и печати имен и кода всех макросов в рабочей книге

tag-icon • tag-icon microsoft-excel vba microsoft-excel-2007
Макрос/код VBA для вывода списка и печати имен и кода всех макросов в рабочей книге

Я использую Excel 2007. Для этого вопроса имя моей рабочей книги — PrintCode.xlsm.

Существует ли макрос или код VBA, который выведет все имена макросов и код в открытой рабочей книге?

Я нашел несколько примеров в Интернете, но ни один из них не работает?

решение1

Я нашел вот это, посмотрите, это то, что вам нужно:Как извлечь имена макросов из книги Excel с помощью Visual Basic 6.0:

Определите процедуру обработчика событий щелчка для кнопки. Используйте следующий код для этой процедуры, чтобы отобразить информацию о макросах, которые определены в C:\Abc.xls:

Private Sub Command1_Click()
    ' Declare variables to access the Excel workbook.
    Dim objXLApp As Excel.Application
    Dim objXLWorkbooks As Excel.Workbooks
    Dim objXLABC As Excel.Workbook

    ' Declare variables to access the macros in the workbook.
    Dim objProject As VBIDE.VBProject
    Dim objComponent As VBIDE.VBComponent
    Dim objCode As VBIDE.CodeModule

    ' Declare other miscellaneous variables.
    Dim iLine As Integer
    Dim sProcName As String
    Dim pk As vbext_ProcKind

    ' Open Excel, and open the workbook.
    Set objXLApp = New Excel.Application
    Set objXLWorkbooks = objXLApp.Workbooks    
    Set objXLABC = objXLWorkbooks.Open("C:\ABC.XLS")

    ' Empty the list box.
    List1.Clear

    ' Get the project details in the workbook.
    Set objProject = objXLABC.VBProject

    ' Iterate through each component in the project.
    For Each objComponent In objProject.VBComponents

        ' Find the code module for the project.
        Set objCode = objComponent.CodeModule

        ' Scan through the code module, looking for procedures.
        iLine = 1
        Do While iLine < objCode.CountOfLines
            sProcName = objCode.ProcOfLine(iLine, pk)
            If sProcName <> "" Then
                ' Found a procedure. Display its details, and then skip 
                ' to the end of the procedure.
                List1.AddItem objComponent.Name & vbTab & sProcName
                iLine = iLine + objCode.ProcCountLines(sProcName, pk)
            Else
                ' This line has no procedure, so go to the next line.
                iLine = iLine + 1
            End If
        Loop
        Set objCode = Nothing
        Set objComponent = Nothing
    Next

    Set objProject = Nothing

    ' Clean up and exit.
    objXLABC.Close
    objXLApp.Quit
End Sub

Связанный контент