Проблема с автоматизацией конкатенации (объединения) VOB-файлов с DVD с помощью FFMPEG

Question

У меня есть библиотека расшифрованных DVD, все из которых имеют свое видео в серии VOB-файлов в обычной папке VIDEO_TS. Мне было интересно, смогу ли я использовать FFMPEG, чтобы объединить их в один MPEG-файл. Поэтому сначала я нашел это (пример предполагает 2 VOB-файла) из старого поста non-stack exchange, и это работает...

ffmpeg -i "concat:VTS_01_1.VOB|VTS_01_2.VOB" -f DVD -c copy output.mpg

ffmpeg иногда жалуется на возможные отсутствующие временные метки, но я не видел никаких проблем с видео, аудио или синхронизацией. Это тоже работает с немного другими жалобами

ffmpeg -i "concat:VTS_01_1.VOB|VTS_01_2.VOB" -f mpeg -c copy output.mpeg

Итак, я написал пакетный файл (windows 10), который собирает количество VOB-файлов, которые я хочу обработать. Я надеялся создать строку "concat" для обработки FFMPEG. Но я сделал это вручную, просто чтобы попробовать вот так...

set concat="concat: VTS_01_1.VOB|VTS_01_2.VOB|VTS_01_3.VOB|VTS_01_4.VOB|VTS_01_5.VOB"

Затем я попытался передать эту строку в FFMPEG следующим образом в моем пакетном файле

ffmpeg -i %concat% -f DVD -c копировать вывод.mpg

Ну, это вообще не работает. Я думаю, FFMPEG не может распознать строковую переменную как замену. Поэтому я посмотрел документацию ffmpeg по теме "concat", и там предлагают использовать список файлов, хранящихся в текстовом файле, например...

file 'VTS_01_1.VOB'
file 'VTS_01_2.VOB' (etc...)

Затем сохраним файл как «mylist.txt» и используем вызов FFMPEG следующим образом...

ffmpeg -f concat -safe 0 -i mylist.txt -c копировать вывод.mpg

Ну, я попробовал, и это не очень хорошо сработало. После первого VOB-файла я получал постоянные предупреждения о переполнении буфера и временных метках, и обычно быстрый процесс конкатенации замедлился до ползания. Предупреждения обычно выглядели так...

[mpeg @ 00000185e32b4200] buffer underflow st=1 bufi=1466 size=1998

[mpeg @ 00000185e32b4200] Non-monotonous DTS in output stream 0:1; previous: 328415794, current: 9265348; changing to 328415795. This may result in incorrect timestamps in the output file.

Так может ли кто-нибудь предложить метод, который РАБОТАЕТ так же, как мой первый пример, но беря список файлов из входного текстового файла?

Answer 1

После множества экспериментов и исследований я обнаружил, что лучше всего сделать скрипт BAT-файла для создания второго скрипта BAT-файла в переменной и сохранить его как временный файл BAt. Затем сконструированный BAT-файл можно создать с помощью специально созданного параметра "concat:" на основе желаемого набора заголовков DVD и обнаруженного количества файлов в наборе заголовков. Единственная ложка дегтя заключается в том, что практически невозможно создать строку в переменной, содержащей символ вертикальной черты (|). Я решил эту проблему, заменив символ '@' во время сборки, а затем использовал утилиту поиска и замены файлов с открытым исходным кодом, чтобы изменить экземпляры '@' на "|". Это работает отлично. Обратите внимание, что я использую Windows 10 и версию FFMPEG git-2020-06-26-7447045, загруженную и установленную в июне 2020 года. Ниже приведен прокомментированный пакетный файл, который я создал, так что если кто-то хочет сделать что-то подобное, он может начать с этого. Я знаю, что это можно улучшить, но это РАБОТАЕТ (всегда хорошее начало)!

::
:: Batch file to automate conversion of a series of VOB files in a DVD
::  titleset into a single MPG file, via FFMPEG. 
:: Pass a name you'd like for the final output movie file in param 1

:: This script needs a a file search and replace utility, and I'm useing
:: SKF (Swiss Army Knife), which is open source and free ...
:: https://sourceforge.net/projects/swissfileknife/

:: Whatever search/replace util you use, you'll have to put it in a
:: 'utilities' folder somewhere in your C: drive, and make sure
:: your system (or USER) PATH variable includes it.

:: Also, unless you have unencrytpted DVD copies to work with, OR a 
:: Decryptor that automatically works in the background (like DVD43),
:: you'll have to start with a program like "1-Click DVD Copy (Pro)".
:: In that case you can put the Resulting VIDEO_TS folder in a temp
:: area on your HD. This will make this batch process run faster, 
:: and eliminate the needs to waste a blank DVD.
 
echo off
SETLOCAL ENABLEDELAYEDEXPANSION

:: Set a path where converted ouptput videos will go
:: Temporary files created by this script will also go here.
set outPath="C:\Users\Public\Videos\Temp"
:: set a path to your DVD. Playable DVDs always have aVIDEO_TS folder
set inPathDVD="Q:\VIDEO_TS"
:: In the event you are making unencrypted copies (maybe with 1-Click), 
:: set that software to put its output files here. In that case,
:: the parameter you pass this script should match the folder name
:: created by that software! 
set inPathHD="C:\Users\Public\Videos\Temp\%1\Video_TS"

:: some variables to construct expecteed files to seach for and gather
set inpTitleSet=VTS_
set inpExt=.VOB
set output=%outPath%\%1.mpg
set outTemp=%outPath%\%1%inpExt%

:: choose whether files come directly from DVD (must be unencrypted!)
:: or defined location on HD
choice /M "Choose Source 1 = DVD  2 = HD Temp Area" /C 12

if ERRORLEVEL 1 set inPath=%inPathDVD%
if ERRORLEVEL 2 set inPath=%inPathHD%

echo input path is: %inPath%
cd /D %inPath%
echo .
echo VOB files from %inpath%...
echo .

:: create filespec for search "VTS_01_*.vob"
set inputFileSpec=%inpTitleSet%*%inpExt% 
dir %inputFileSpec%
echo .
:: select desired titleset. Usually the group with the 
:: biggest file sizes is  the main movie titleset.
:: You'll be entering the digit after "VTS_0"
choice /M "Select Desired Titleset (digit after VTS_): " /C 12345678
echo you picked %ERRORLEVEL%
set inpTitleSet=%inpTitleSet%0%ERRORLEVEL%_
set inputFileSpec=%inpTitleSet%*%inpExt% 

:: use a brute force loop to calculate number of 
:: files matching %inputFileSpec% and display them.
:: Note that the '0' file is usually title/menu information,
:: and is skipped by making the %start% var '1'

echo files selected...
echo .
set start=1
:loop0
set tmp=%inpTitleSet%%start%%inpExt%
IF EXIST %tmp% (
echo %tmp%
set /A start=start+1
GOTO loop0
)
set /A count=%start%-1
echo .
:: confirm total files
echo Total Files = %count%

:: safety exit, in odd event where no movie files found
if %count% NEQ 0 GOTO continue1
echo .
echo Must Exit... no Files Found.
goto exit
:continue1

:: Build string containing of file names for FFMPEG "concat:" parameter.
:: Another Brute force loop. Again file *0.VOB will be skipped, 
:: by making loop start=1:: 

:: set an 'empty' variable
set cc=
set start=1
:: create a temp substitute for the pipe "|" character, 
:: because | can't be cant be used in a script (^| or similar
::  constructs just won't work here). So I'll use '@' and change it 
:: later with a file search/replace utility.
set mypipe=@

:loop1
set tmp=%inpTitleSet%%start%%inpExt%
if %start% EQU %count% set mypipe=
IF EXIST %tmp% (
set cc=%cc%%inp%%tmp%%mypipe%
set /A start=start+1
GOTO loop1
)

:: create whole FFMPEG command as a string
set ffm=ffmpeg -i "concat:%cc%" -f DVD -c copy %output%

:: put it in a tmp batch file
set cmdfile=tmp.bat
echo %ffm%  > %outPath%\%cmdfile%

:: now use SKF to replace the @ chars with |
:: if you have another search/replace utility, feel free to use it.
sfk replace %outPath%\%cmdfile% "/@/|/" -yes -quiet

:: prove string in batch file looks right. You can delete
:: these two lines if you want.
echo Final command...
type %outPath%\%cmdfile%

:: run the new batch file... Give user chance to start process
@pause
call %outPath%\%cmdfile%

:: delete batch file?
del %outPath%\%cmdfile%
echo .
echo .
echo %output% converted file should be ready

ENDLOCAL
:exit