☰

Excel COUNTIF с несмежными именованными диапазонами

tag-icon • tag-icon microsoft-excel
Excel COUNTIF с несмежными именованными диапазонами

Я использую формулу для проверки данных, чтобы скрыть используемые имена, например: =IF(COUNTIF(DrawUsed, [Players])>=1, "", [Players]), где DrawUsed— именованный диапазон. Проблема в том, что моя таблица выглядит так:

введите описание изображения здесь

Мне нужно, Blind Draw Teamчтобы столбцы были первым параметром COUNTIF, так как если имя используется в первом столбце, оно не должно быть доступно для третьего Blind Draw Teamстолбца. Проблема в том, что эта формула с определенным именованным диапазоном =Blind!$B$2:$B$27,Blind!$I$2:$I$27,Blind!$P$2:$P$27не приводит ни к чему, кроме #VALUE!ошибок.

Я не могу определить непрерывный диапазон, потому что Buyerстолбцы должнынетзависеть от значений Blind Draw Teamи не должны скрывать используемые имена.

Есть ли у кого-нибудь совет?

решение1

Я решил эту проблему, определив 3 отдельных диапазона и следующую формулу:

=IF(
    OR(
        COUNTIF(BlindUsed1, [Players])>=1,
        COUNTIF(BlindUsed2, [Players])>=1,
        COUNTIF(BlindUsed3, [Players])>=1
    ),
    "", 
    [Players]
)

Возвращается для удобства чтения.

Обновлять

Решение 2: INDIRECTможет обрабатывать несмежные диапазоны. У меня был диапазон, который был буквально просто кучей несмежных ячеек. Я определил его так:

=INDIRECT(
    {
        "Sunday!$F$7",
        "Sunday!$F$15",
        "Sunday!$F$23",
        "Sunday!$F$31",
        "Sunday!$F$39",
        "Sunday!$M$7",
        "Sunday!$M$15",
        "Sunday!$M$23",
        "Sunday!$M$31",
        "Sunday!$M$39",
        "Sunday!$T$7",
        "Sunday!$T$15",
        "Sunday!$T$23",
        "Sunday!$T$31",
        "Sunday!$T$39"
    }
)

Затем COUNTIFработает в диапазоне: =COUNTIF(SundayCaptains,[Player]). Единственный недостаток этого метода в том, что значения не будут обновляться, если вы переименуете рабочий лист.

Связанный контент