☰

Почему echo «$USER:staff» выдает zsh: плохая подстановка?

tag-icon • tag-icon zsh
Почему echo «$USER:staff» выдает zsh: плохая подстановка?

Озадачен, потому что echo "PATH=$PATH:/usr/local/sbin"это не так (думал, что это как-то связано с :).

Кроме того, в Bash обе команды работают так, как я и ожидал.

$ echo "PATH=$PATH"
PATH=/usr/local/bin

$ echo "PATH=$PATH:/usr/local/sbin"
PATH=/usr/local/bin:/usr/local/sbin

$ echo "$USER:staff"
zsh: bad substitution

решение1

Потому что :sпосле этого $USERинтерпретируется какмодификатор расширения. Вы можете ясно увидеть это, если сделаете следующее:

% autoload -Uz compinit; compinit       # Init completion system
% zstyle ':completion:*' group-name ''  # Enable completion grouping
% zstyle ':completion:*' format '%d'    # Add titles to the groups
% print $USER: # and press Tab or ^D right after the `:`
modifier
&  -- repeat substitution
A  -- as ':a', then resolve symlinks
P  -- realpath, resolve '..' physically
Q  -- strip quotes
a  -- absolute path, resolve '..' lexically
c  -- PATH search for command
e  -- leave only extension
g  -- globally apply s or &
h  -- head - strip trailing path element
l  -- lower case all words
q  -- quote to escape further substitutions
r  -- root - strip suffix
s  -- substitute string
t  -- tail - strip directories
u  -- upper case all words

И как вы можете видеть из списка выше, :/это не модификатор расширения.

Рекомендуется ли всегда использовать ${PATH}, ${USER}, и т. д. тогда?

Нет, обычно можно просто использовать $USER, ноиногда,как видите, использовать обязательно ${USER}. :)

Однако, относительно кода в вашем вопросе, я могу дать вам две другие рекомендации по использованию в Zsh:

% print $PATH
/usr/local/bin

% print $path
/usr/local/bin

% path+=/usr/local/sbin  # $path is an array, not a string

% print $PATH            # $path and $PATH are "tied" & automatically in sync
/usr/local/bin:/usr/local/sbin

% print -c $path         # Print the items in columns, like `ls`
/usr/local/bin   /usr/local/sbin

% print -l $path         # Print one item per line, like `ls -l`
/usr/local/bin
/usr/local/sbin

% path+=/usr/local/sbin

% print -c $path       
/usr/local/bin   /usr/local/sbin  /usr/local/sbin

% typeset -U PATH path   # Make each item unique/Eliminate duplicates

% print -c $path       
/usr/local/bin   /usr/local/sbin

Связанный контент