☰

можно ли настроить сочетание клавиш для переключения настроек системы на Mac

tag-icon • tag-icon macos mac keyboard-shortcuts applescript system-preferences
можно ли настроить сочетание клавиш для переключения настроек системы на Mac

Мне очень часто приходится заходить в Системные настройки, чтобы переключить настройки трекпада или изменить настройки цвета дисплея в специальных возможностях. Я не могу найти способ сделать это с помощью сочетаний клавиш. Для некоторых из этих настроек есть внешние приложения, которые могут выполнить эту цель, но для таких вещей, как изменение настройки масштабирования специальных возможностей с разделенного экрана на картинку в картинке, похоже, возможно только через панель системных настроек.

Если есть способ получить к ним доступ с помощью bash/applescripts или любого другого типа скриптов, это еще лучше, поскольку я знаю, как с ними обращаться.

решение1

Theпример AppleScript код, показанный ниже, был протестирован подmacOS КаталинаиmacOS Биг Сур сЯзык и регионнастройки вСистемные настройкиустановлен вАнглийский (США) — Начальныйи у меня работало без проблем 1 .

  • 1 Предполагает необходимую и соответствующую обстановку вСистемные настройки>Безопасность и конфиденциальность>Конфиденциальностьбыли установлены/решены по мере необходимости.

Пример AppleScript код:

if running of application "System Preferences" then
    try
        tell application "System Preferences" to quit
    on error
        do shell script "killall 'System Preferences'"
    end try
    delay 0.1
end if

repeat while running of application "System Preferences" is true
    delay 0.1
end repeat

tell application "System Preferences" to ¬
    reveal anchor "Seeing_Zoom" of ¬
        pane id "com.apple.preference.universalaccess"

tell application "System Events"
    tell application process "System Preferences"
        tell pop up button 1 of group 1 of window 1
            if its value is "Split screen" then
                click
                delay 0.1
                click menu item "Picture-in-picture" of menu 1
            else if its value is "Picture-in-picture" then
                click
                delay 0.1
                click menu item "Split screen" of menu 1
            else
                click
                delay 0.1
                click menu item "Split screen" of menu 1
            end if
        end tell
    end tell
end tell

delay 0.2

tell application "System Preferences" to quit

Примечания:

Theпример AppleScript кодможет быть использован вАвтоматизатор Обслуживание/Быстрое действиеиспользуяЗапустить AppleScript действие, заменяя значение по умолчаниюкодс ним, и назначилСочетание клавишв:Системные настройки>Клавиатура>Ярлыки>Услуги

Обратите внимание, что назначениеглобальная комбинация клавишможет быть трудно не наступить наСочетание клавишиз любогоприложениеимеет фокус, когдаглобальная комбинация клавишнажат и также может потребоваться добавление того, чтоприложениек:Системные настройки>Безопасность и конфиденциальность>Конфиденциальность

Возможно, лучше использовать любой изсторонние приложениякоторый может справиться с запускомAppleScript скриптысСочетание клавишчем использоватьАвтоматизатор Обслуживание/Быстрое действие. Я используюFastScriptsи я не связан с его разработчиком, а просто довольный пользователь продукта.

Theпример AppleScript кодтакже может быть использован вAppleScript приложениетакже.

Как закодировано, если текущийценитьпринадлежащийСтиль масштабирования: всплывающее менюустановлен либоРазделенный экранилиКартинка в картинкеон переключается между ними. Если он установлен наПолноэкранныйон переключает его наРазделенный экран.

Theпример AppleScript кодиспользуетСкриптинг пользовательского интерфейсаи как таковые некоторыеЭлементы пользовательского интерфейсаможет ненадолго появиться на экране, и в этом конкретном случае использования в закодированном виде можно будет увидетьСтиль масштабирования: всплывающее менюпри переключении между вариантами выбора.

Если вы предпочитаете увидеть всеПользовательский интерфейсизСистемные настройкив то время как он переключает цельвсплывающее меню, затем:

Изменять:

tell application "System Preferences" to ¬
    reveal anchor "Seeing_Zoom" of ¬
        pane id "com.apple.preference.universalaccess"

К:

tell application "System Preferences"
    reveal anchor "Seeing_Zoom" of ¬
        pane id "com.apple.preference.universalaccess"
    activate
end tell

Обратите вниманиепример AppleScript кодэто просто то, что и без каких-либо включенныхобработка ошибокне содержит никаких дополнительныхобработка ошибоккак это может быть уместно. Бремя добавления любогообработка ошибоккак может быть уместно, необходимо или желательно. Посмотрите напытаться заявлениеиошибка заявлениевРуководство по языку AppleScript. Смотрите также,Работа с ошибками. Кроме того, использованиезадерживать командаможет быть необходимо между событиями, где это уместно, например delay 0.5, сценитьпринадлежащийзадерживатьустановлен соответствующим образом.

Связанный контент