☰

Переупорядочивание данных столбцов в алфавитном порядке

tag-icon • tag-icon linux awk
Переупорядочивание данных столбцов в алфавитном порядке

Я хочу изменить порядок данных в столбце в алфавитном порядке.

Вход

c,a,b
e,k,d

Выход

a,b,c
d,e,k

В настоящее время я использую следующий код

awk -F"," -v OFS="," '{ 
if($1<=$2 && $2<=$3) 
{print $1,$2,$3} 
else if($1<=$2 && $3<=$2) 
{print $1,$3,$2} 
else if($2<=$1 && $1<=$3) 
{print $2,$1,$3} 
else if($2<=$1 && $3<=$1) 
{print $2,$3,$1} 
else if($3<=$2 && $2<=$1) 
{print $3,$2,$1} 
else 
{print $3,$1,$2}}' test.txt

Не могли бы вы мне помочь с более простым решением для обработки файлов, содержащих 4 или более столбцов?

решение1

Если вас устраивает perl:

$ perl -F, -lane 'print join ",", sort @F' ip.txt
a,b,c
d,e,k

-F,указывает входную строку, которая будет разделена, ,как разделитель, а результат доступен через @Fмассив

sort @Fотсортирует в алфавитном порядке, а полученный массив будет объединен с joinиспользованием ,в качестве разделителя


СGNU awk

$ awk 'BEGIN{PROCINFO["sorted_in"] = "@val_str_asc"}
       {s = ""; c=0; split($0,a,",");
        for(k in a) s = c++ ? s "," a[k] : a[k];
        print s}' ip.txt
a,b,c
d,e,k

ВидетьРуководство gawk: Использование предопределенных порядков сканирования массивадля получения подробной информации о порядке массива, использованном выше

решение2

С помощью GNU awk для sorted_in:

$ cat tst.awk
BEGIN {
    FS=OFS=","
}
{
    sub(/\r$/,"")
    print sort($0)
}

function sort(inStr,    arr,idx,sep,outStr) {
    PROCINFO["sorted_in"] = "@val_str_asc"
    split(inStr,arr)
    for (idx in arr) {
        outStr = outStr sep arr[idx]
        sep = OFS
    }
    return outStr
}

$ awk -f tst.awk file
a,b,c
d,e,k

или с любым awk, но будет выполняться гораздо медленнее, поскольку он порождает оболочку для вызова UNIX sortдля каждой строки ввода:

$ cat tst.awk
BEGIN {
    FS=OFS=","
}
{
    sub(/\r$/,"")
    print sort($0)
}

function sort(inStr,    cmd,line,sep,outStr) {
    gsub(/,/,"\n",inStr)
    cmd = "printf \047%s\n\047 \047" inStr "\047 | sort"
    while ( (cmd | getline line) > 0 ) {
        outStr = outStr sep line
        sep = OFS
    }
    close(cmd)
    return outStr
}

$ awk -f tst.awk file
a,b,c
d,e,k

Это sub(/\r$/,"")связано с тем, что в опубликованном вами образце входных данных есть окончания строк DOS, но в опубликованном ожидаемом выводе их нет.

решение3

perl -nlE 'say join ",", sort split ","'   file.txt

Объяснение:

            for each line like "r,d,a":
 "r,d,a"
    ↓          split ","  it
("r","d","a")
    ↓          sort       it
("a","d","r")
    ↓          join ","   it
 "a,d,r"
               say it

Связанный контент