☰

как мне сделать эти данные в отдельных столбцах

tag-icon • tag-icon bash text-processing
как мне сделать эти данные в отдельных столбцах 
Frequencies -- 1403.6738 1403.6738 1403.6738
IR Inten -- 25.0809 25.0809 25.0809

Я хочу получить две колонки

Frequencies     IR Inten
1403.6738       25.0809

и так далее

решение1

Использование Raku (язык программирования, ранее известный как Perl6)

У Raku есть удобный Zоператор для решения таких задач, позволяющий «сжимать» элементы, по одному из каждого списка:

~$ raku -e 'my @array1 = lines(); put ( [Z] @array1[0].words, @array1[1].words).join("\n");'  Freq_IR.txt
Frequencies IR_Inten
-- --
1403.6738 25.0809
1403.6738 25.0809
1403.6738 25.0809

Примечание: Мне пришлось исправить строку заголовка выше, чтобы второй столбец был озаглавлен " IR_Inten". Вы можете отредактировать вручную или запустить код ниже, прежде чем переставлять данные с помощью кода выше:

~$ raku -pe 's/IR \s Inten/IR_Inten/;'  Freq_IR.txt > Freq_IR2.txt

НТН.

https://raku.org
https://docs.raku.org/language/operators#Zip_metaoperator
https://docs.raku.org/language/operators#index-entry-[+]_(reduction_metaoperators)

решение2

Использование любого awk в любой оболочке на любой машине Unix:

$ awk -F' -- ' -v OFS='\t' '
    { hdr[NR]=$1; n=split($2,v," "); for (i in v) vals[NR,i]=v[i] }
    END { print hdr[1], hdr[2]; for (i=1; i<=n; i++) print vals[1,i], vals[2,i] }
' file
Frequencies     IR Inten
1403.6738       25.0809
1403.6738       25.0809
1403.6738       25.0809

и работать для любого количества выходных строк и столбцов:

awk -F' -- ' -v OFS='\t' '
    { hdr[NR]=$1; n=split($2,v," "); for (i in v) vals[NR,i]=v[i] }
    END {
        for (c=1; c<=NR; c++) {
            printf "%s%s", hdr[c], (c<NR ? OFS : ORS)
        }
        for (r=1; r<=n; r++) {
            for (c=1; c<=NR; c++) {
                printf "%s%s", vals[c,r], (c<NR ? OFS : ORS)
            }
        }
    }
' file

решение3

Используя awk, мы можем выполнить преобразование данных.

awk -F ' -- ' '
{
  # populate the array
  a[++N] = $1; split($2, t, " ")
  for (k in t) { a[++N] = t[k] }
}
END {ORS = ""
  for (c=i=1; i<=N/NR; i++) {
    for (j=i; j<=N; j+=N/NR) {
      print a[j] (c++%NR ? "\t" : "\n")
    }
  }
}
' file
Frequencies IR Inten
1403.6738   25.0809
1403.6738   25.0809
1403.6738   25.0809

Основная идея заключается в том, чтобы сначала заполнить массив и записать длину массива в конце. Затем разбить массив на N/NR частей и выбрать соответствующие элементы из каждой части. В других языках, таких как Python, эта операция называется zip.

Связанный контент