☰

стили линий не применяются в gnuplot (epslatex)

tag-icon • tag-icon gnuplot
стили линий не применяются в gnuplot (epslatex)

Здравствуйте, я хотел бы нарисовать 2 кривые на одном графике с помощью gnuplot (терминал epslatex). Я использую скрипт gnuplot, который работает отлично, за исключением того, что он не применяет цвета линий, определенные с помощью команды set style line.

Вот сценарий:

set terminal epslatex color colortext size 9cm,5cm
set size 1,1
set output "lorenzov_faktor.tex"

set xrange [0:10]
set yrange [0:10]

set xtics ("$0c$" 0, "$c$" 10)
set ytics ("$0$" 0, "$1$" 1, "$\\infty$" 10)

set style line 1 lc rgb "#FF0055"
set style line 2 lc rgb "#2C397D"

unset grid

set ylabel "$\\gamma$"
set xlabel "$u$"

set key left top

f(x) = 1/sqrt(1 - (x/10)**2) 
g(x) = 1

set xrange [0:11]
set yrange [0:9]

plot f(x) ls 2 lw 3 lt 1 title "$\\gamma$", g(x) ls 1 lw 1 lt 2 notitle

В результате получается график, цвета которого не соответствуют моим определениям стилей линий: введите описание изображения здесь

решение1

Вам нужно удалить lt 1и lt 2из вашего скрипта, потому что они восстанавливают типы линий по умолчанию вместо ваших стилей линий, определенных пользователем. В качестве альтернативы вы можете изменить тип линии (сплошная, пунктирная и т. д.), не влияя на цвет, используя ltкогда вы это делаете set style line.

set style line 1 lc rgb "#FF0055" lt 1
set style line 2 lc rgb "#2C397D" lt 3

...

plot f(x) ls 2 lw 3 title "$\\gamma$", g(x) ls 1 lw 1 notitle

Связанный контент