☰

Как нарисовать такие мишени?

tag-icon • tag-icon tikz-pgf
Как нарисовать такие мишени?

Я хотел бы показать некоторые свойства стимуляторов в статистике. Я совсем новичок в LaTeX, поэтому мне нужна помощь.

в розыске

решение1

Такого рода диаграмму довольно легко нарисовать, используятикз/пгф. Это обширное и хорошо написанное руководство, поэтому, прочитав его, вы получите хорошее представление о том, что вам нужно сделать. Вот похожий пример, с которого можно начать:

\documentclass[border=5mm,tikz]{standalone}
\usepackage{mwe}
\usepackage{tikz}
\begin{document}

  \begin{tikzpicture}
    \draw (0,0) circle[radius=1];
    \draw[red] (0,0) circle[radius=2];
    \draw[blue] (0,0) circle[radius=3];
    \foreach \x in {-1,0,1} {
      \foreach \y in {-1,0,1} {
        \node[fill=white] at (\x,\y) {x};
      }
    }
  \end{tikzpicture}

\end{document}

Получается следующая картина:

введите описание изображения здесь

Если вы хотите нарисовать x' в определенном списке координат, самый простой способ сделать это — сделать что-то вроде:

\foreach \x/\y in {-1/1,0/1,-1/0,-1/0,0/0,1/0,-1/-1,0/-1,-1/-1} {
    \node[fill=white] at (\x,\y) {x};
}

Фактически это эквивалентно коду в примере выше.

решение2

Вы также можете нарисовать что-то подобное красиво вМетапост, что вам может понравиться. Здесь я использовал встроенную normaldeviateкоманду для генерации некоторых подходящих случайных попаданий в цель.

введите описание изображения здесь

prologues := 3;
outputtemplate := "%j%c.eps";
beginfig(1);
numeric s;
picture target, cross;
s = 24;
target = image(for r=1 upto 3: draw fullcircle scaled (r*s); endfor);
cross  = image(draw (left--right) rotated 45; draw (left--right) rotated -45;);
picture A, B, C, D;
A = target shifted (-2s,+2s);
B = target shifted (+2s,+2s);
C = target shifted (-2s,-2s);
D = target shifted (+2s,-2s);

% mark "n" hits centered at "p" with "r" degree of scattering
vardef mark_hits(expr n, p, r) = 
  for i=1 upto n:
     draw cross shifted p shifted (r * normaldeviate, r * normaldeviate);
  endfor
enddef;

draw A; mark_hits(12, center A, 3); 
draw B; mark_hits(12, center B, 12);
draw C; mark_hits(12, center C shifted (-s/2,s/2), 3);
draw D; mark_hits(12, center D shifted (s/2,-s/2),12);

label.bot("(a)", 1/2[llcorner A, lrcorner A]);
label.bot("(b)", 1/2[llcorner B, lrcorner B]);
label.bot("(c)", 1/2[llcorner C, lrcorner C]);
label.bot("(d)", 1/2[llcorner D, lrcorner D]);

setbounds currentpicture to bbox currentpicture scaled 1.05;

endfig;


end

Связанный контент