☰

сравнение строк с помощью awk и while read line

tag-icon • tag-icon text-processing sed awk search
сравнение строк с помощью awk и while read line

У меня есть два файла, один с 17 тыс. строк, а другой с 4 тыс. строк. Я хотел сравнить позицию 115 с позицией 125 с каждой строкой во втором файле и, если есть совпадение, записать всю строку из первого файла в новый файл. Я придумал решение, в котором я читаю файл с помощью 'cat $filename | while read LINE'. но это занимает около 8 минут. Есть ли другой способ, например, использование 'awk', чтобы сократить время этого процесса.

мой код

cat $filename | while read LINE
do
  #read 115 to 125 and then remove trailing spaces and leading zeroes
  vid=`echo "$LINE" | cut -c 115-125 | sed 's,^ *,,; s, *$,,' | sed 's/^[0]*//'`
  exist=0
  #match vid with entire line in id.txt
  exist=`grep -x "$vid" $file_dir/id.txt | wc -l`
  if [[ $exist -gt 0 ]]; then
    echo "$LINE" >> $dest_dir/id.txt
  fi
done

решение1

Следующий код должен работать, если его обновить, чтобы убрать пробелы:

#!/usr/bin/awk -f
# NR is the current line number (doesn't reset between files)
# FNR is the line number within the current file
# So NR == FNR  takes only the first file
NR == FNR {
    # Mark the current line as existing, via an associative array.
    found[$0]=1

    # Skip to the next line, so we don't go through the next block
    next
}
{
    # Take the columns we're looking for
    cols = substr($0,115,11)

    # Strip whitespace (space and tab) from the beginning (^) and end ($) 
    gsub(/^[ \t]+/,"", cols)
    gsub(/[ \t]+$/,"", cols)

    # Check the associative array to see if this was in the first file
    # If so, print the full line
    if(found[cols]) print;
}

Поместите его в файл и вызовите одним из следующих способов:

awk -f script.awk patterns.txt full.txt
./script.awk patterns.txt full.txt

Связанный контент