☰

Реализуйте политику подписи в Exchange 2003 с использованием полей Active Directory

tag-icon • tag-icon active-directory exchange outlook
Реализуйте политику подписи в Exchange 2003 с использованием полей Active Directory

Наша организация решила, что ей необходимо иметь стандартный блок подписи для всех пользователей на основе их имени, должности, контактных данных и местонахождения офиса, которые хранятся в Active Directory.

Нашел ли кто-нибудь удобное решение для автоматического создания подписей Outlook/Exchange 2003 на основе полей Active Directory?

решение1

Я давний клиент и поклонникУтилиты Exclaimer Mail.

Он находится на вашем сервере Exchange и имеет множество настраиваемых правил, которые определяют, применять ли стационарный или нет. Я добавляю в начало всех писем, отправляемых за пределы, наш корпоративный логотип, а также имя человека, должность и различные номера телефонов внизу — все это извлекается из Active Directory.

Я пользовался службой поддержки только один раз, но они были очень дружелюбны, компетентны и решили мою проблему очень быстро.

решение2

Мне очень повезло с написанным мной скриптом. Он записывает данные из различных полей AD в невидимый документ Word, затем копирует его в Outlook 2007 как подпись по умолчанию и ответ.

Я отошел от автоматического запуска при каждом входе в систему. Очень редко у меня возникали проблемы при первом входе пользователя в систему, где Outlook еще не мог открыться без прохождения мастера. На данный момент это GPO, который просто помещает ярлык на рабочие столы пользователей под названием «Сброс подписи электронной почты». Это также позволяет пользователям иметь подписи, отличные от подписей по умолчанию, без их переопределения каждый раз.

On Error Resume Next

Set objSysInfo = CreateObject("ADSystemInfo")

strUser = objSysInfo.UserName
Set objUser = GetObject("LDAP://" & strUser)

strName = objUser.FullName
strTitle = objUser.Title
strDepartment = objUser.Department
strCompany = objUser.Company
strPhone = objUser.telephoneNumber
strFax = objUser.faxNumber

strStreet = objUser.StreetAddress
strCity = objUser.L
strState = objUser.St
strPOBox = objUser.postalCode

strFirstName = objUser.givenName
strInitials = objUser.initials
strLastName = objUser.sn
If strInitials = "" Then
    strFullName = strFirstName & " " & strLastName
Else
    strFullName = strFirstName & " " & strInitials & ". " & strLastName
End If

Set objWord = CreateObject("Word.Application")

Set objDoc = objWord.Documents.Add()
Set objSelection = objWord.Selection
objSelection.Style = "No Spacing" 
objSelection.Font.Name = "Calibri"
objSelection.Font.Size = "11"

Set objEmailOptions = objWord.EmailOptions
Set objSignatureObject = objEmailOptions.EmailSignature

Set objSignatureEntries = objSignatureObject.EmailSignatureEntries

objSelection.TypeParagraph()
objSelection.TypeText "Sincerely,"
objSelection.TypeParagraph()
objSelection.TypeParagraph()
objSelection.TypeText "ORGANIZATION NAME"
objSelection.TypeParagraph()
objSelection.TypeParagraph()
objSelection.TypeText strFullName & ", " & strTitle
'objSelection.TypeText strName & ", " & strTitle
objSelection.TypeParagraph()
objSelection.TypeParagraph()
objSelection.TypeText strStreet
objSelection.TypeParagraph()
objSelection.TypeText strCity & ", " & strState & " " & strPOBox
objSelection.TypeParagraph()
objSelection.TypeText "Desk: " & strPhone
objSelection.TypeParagraph()
objSelection.TypeText "Fax:    " & strFax
objSelection.TypeParagraph()

'Hyperlink below
objDoc.Hyperlinks.Add objSelection.Range, "www.yoursitename.com", "", "", "www.yoursitename.com", ""

objSelection.TypeParagraph()
objSelection.TypeParagraph()

'Picture below
Set objShape = objSelection.InlineShapes.AddPicture("\\fileserver\path\to\image.BMP")

Set objSelection = objDoc.Range()

objSignatureEntries.Add "AD Signature", objSelection
objSignatureObject.NewMessageSignature = "AD Signature"
objSignatureObject.ReplyMessageSignature = "AD Signature"

objDoc.Saved = True
objWord.Quit

Если у вас есть вопросы, просто дайте мне знать!

Связанный контент