☰

Как узнать владельца файла в AIX, не портя вывод ls?

tag-icon • tag-icon files aix stat
Как узнать владельца файла в AIX, не портя вывод ls?

Как я мог бынадежнополучить владельца файла в AIX? По надежности, я не хочу анализировать вывод ls. В Linux я бы просто сделал a stat --printf=%U foo, но я работаю в AIX 6.1 и 7.1. Я знаю, что могу сделать , но поскольку в AIX istatнет опции , мне все равно придется искажать вывод с помощью и , поэтому это не так желательно. Другими словами, как я могу эмулировать Linux, используя только основные утилиты AIX?--printfistatgrepawkstat --printf=%U foo

решение1

Это скрипт, который я написал некоторое время назад, чтобы получить утилиту типа stat(1) в AIX. Только что добавил %U! Я обнаружил, что более полезно использовать опцию -c, которая ведет себя немного иначе, чем --printf. Включает удобную локальную копию массива stat perl в качестве блока комментариев.

#!/usr/bin/env perl -w
# emulate GNU coreutils stat command in a limited way
# -- only implemented a subset of the stat() options

use strict;
use Getopt::Std;
our $opt_c;

getopts('c:') or die "Usage: $0 [ -c (%n %i %u %g %s %U %X %Y %Z) ] file ...";
# default format is empty (not useful, but avoids 'undef' errors later)
$opt_c |= '';

for (@ARGV) {
  my @s = stat;
  next unless @s; # silently fail on to the next file
  my $p = $opt_c; # make a copy of the format string to mangle for each file

  # mangle and print
  $p =~ s/%n/$_/g;
  $p =~ s/%i/$s[1]/g;
  $p =~ s/%u/$s[4]/g;
  $p =~ s/%g/$s[5]/g;
  $p =~ s/%s/$s[7]/g;
  $p =~ s/%U/getpwuid($s[4])/eg;
  $p =~ s/%X/$s[8]/g;
  $p =~ s/%Y/$s[9]/g;
  $p =~ s/%Z/$s[10]/g;
  print "$p\n";

  #                 0 dev      device number of filesystem
  #                 1 ino      inode number
  #                 2 mode     file mode  (type and permissions)
  #                 3 nlink    number of (hard) links to the file
  #                 4 uid      numeric user ID of file's owner
  #                 5 gid      numeric group ID of file's owner
  #                 6 rdev     the device identifier (special files only)
  #                 7 size     total size of file, in bytes
  #                 8 atime    last access time in seconds since the epoch
  #                 9 mtime    last modify time in seconds since the epoch
  #                10 ctime    inode change time in seconds since the epoch (*)
  #                11 blksize  preferred block size for file system I/O
  #                12 blocks   actual number of blocks allocated

}

Связанный контент