☰

Windows 7 功能或免費軟體可讓視窗始終位於其他視窗下方

tag-icon • tag-icon windows-7 window ordering always-on-top
Windows 7 功能或免費軟體可讓視窗始終位於其他視窗下方

某些程式（例如 GridMove 和 XNeat）允許使用者使用「Always On Top」命令將給定視窗保持在其他視窗上方。除了使所有其他視窗「始終在頂部」之外，是否有一種方法可以使用任何 Windows 7 命令或免費軟體來執行相反的操作，即「始終在底部」？

有時，將聊天程式（在其中進行打字）保留在所有視窗下方，並且僅透過視窗間隙可見最新訊息和文字輸入字段，而不會使聊天程式的 UI 的其餘部分弄亂空間。

答案1

很久以前，Windows 有一個名為 X-Mouse 的 PowerToy（後來在 TweakUI 中），除此之外，它支援舊式 X“焦點跟隨滑鼠”，其中“焦點”和“前景”不是同一件事。我不相信它已經被維護了（最後一次出現是針對 WinXP）。

雖然我沒有廣泛使用它，但免費的 Windows 腳本編寫工具自動IT可以用一個簡短的腳本做你想做的事：

#include <WinAPI.au3>
#include <Constants.au3>
#include <WindowsConstants.au3>
#include <MenuConstants.au3>
#include <SendMessage.au3>

Local $hWnd,$flags,$regexp

Func MyExit() 
    MsgBox(0,"Drop Window","Quitting!",2) 
    Exit 0
EndFunc

$flags = BitOr($SWP_NOMOVE,$SWP_NOSIZE,$SWP_NOACTIVATE,$SWP_ASYNCWINDOWPOS,$SWP_NOSENDCHANGING) 

;; hot key to call exit: ALT + F11
HotKeySet("!{F11}","MyExit")

;; application window title
$regexp=".*Notepad$"

;; 10 second time out on first startup, 
$hWnd = WinWait("[REGEXPTITLE:" & $regexp & "]", "", 10)
;; or wait forever
;$hWnd = WinWait("[REGEXPTITLE:" & $regexp & "]")

If ($hWnd) Then
    ;; uncomment next line to maximize window first
    ;_SendMessage($hWnd,$WM_SYSCOMMAND,$SC_MAXIMIZE)

    _WinAPI_SetWindowPos($hWnd, $HWND_BOTTOM, 0, 0, 0, 0, $flags);

    While 1
        If WinWaitActive($hWnd,"",10) Then
            _WinAPI_SetWindowPos($hWnd, $HWND_BOTTOM, 0, 0, 0, 0, $flags);
        EndIf
        ;; check for new window
        $hWnd = WinWait("[REGEXPTITLE:" & $regexp & "]","",1) 

        ;; uncomment next 3 lines to quit if no window
        ;if (NOT $hWnd) Then
        ;    MyExit()
        ;EndIf

        Sleep(250)
    Wend
Else
    MsgBox(0,"Drop Window","No window title matching /" & $regexp & "/") 
EndIf

「topmost」是 WM 維護的一個持久視窗屬性，沒有等效的“bottommost”，所以我們必須稍微修改一下它。

While 循環等待應用程式獲得前台，然後再次將其置於前台，同時保持鍵盤焦點。模態彈出視窗有時可能會幹擾這一點，但它應該非常有用。 Alt+F11 可隨時登出。

更改 $regexp 以符合“mIRC”或其他內容。上面的方法一次只能可靠地處理一個視窗。閱讀 WinWait() 的 AutoIT 文檔，以了解如何匹配視窗而不是按視窗標題。

儲存到 dropwindow.au3 並使用“autoit3 dropwindow.au3”運行它。

http://www.autoitscript.com/site/autoit/downloads/

答案2

如果您的電腦配備了 ATI Radeon 顯示卡，您可以將 HydraGrid 與最新的 ATI 驅動程式和實用程式一起使用，如果沒有溫斯普利特革命。

相關內容