☰

尋找 3 列中的唯一值

tag-icon • tag-icon microsoft-excel-2010
尋找 3 列中的唯一值

我的Excel中有3列。我想在 A、B 和 C 列中找到唯一值。

所以：

  1. 透過查看 A 列，我想找到 B 或 C 中沒有的唯一值。
  2. 透過查看 B 列，我想找到 A 列或 C 列中沒有的唯一值。
  3. 透過查看 C 列，我想找到 A 列或 B 列中沒有的唯一值。

這是我在A欄輸入的內容

=IF(OR(MATCH(A3,$B$3:$B$631,0),(MATCH(A3,$C$3:$C$408,0))),"Match",A3)

這是我在B欄輸入的內容

=IF(OR(MATCH(B3,$A$3:$A$857,0),(MATCH(B3,$C$3:$C$408,0))),"Match",B3)

這是我在 C 列中輸入的內容

=(IF(OR(MATCH(C3,$A$3:$A$857,0),(MATCH(C3,$B$3:$B$631,0))),"Match",C3)

這給了我三列中的重複值，我需要它們是唯一的。也許我只是讓事情變得非常複雜。關於如何做到這一點有什麼想法嗎？

表格範例：

A   B   C
1   2   2
2   3   3
3   7   7
4   8   11
5   9   12
6   10  13

在本例中，我希望每列都有唯一的 #。因此，對於 A 列，不在 B 列或 C 列中的唯一值 = 到 1,4,5,6。在 B 列中，不在 A 或 C 中的唯一值是 =8,9, 10。 在 C 列中，不在 B 或 C 中的唯一值是 = 11, 12, 13。的D、E、F 列中的公式。

ABC 1 2 2 2 3 3 3 7 7 4 8 11 5 9 12 6 10 13

在本例中，我希望每列都有唯一的 #。因此，對於 A 列，不在 B 列或 C 列的 unquie 值 = 1,4,5,6。在 B 列中，不在 A 或 C 中的唯一值是 =8,9, 10。 在 C 列中，不在 B 或 C 中的唯一值是 = 11, 12, 13。的D、E、F 列中的公式。

答案1

您可以在 D1 中使用如下所示的陣列公式† ：

=IFERROR(INDEX($A$1:$A$6,SMALL(IF(ISERROR(MATCH($A$1:$A$6,$B$1:$B$6,0))*ISERROR(MATCH($A$1:$A$6,$C$1:$C$6,0)),ROW($A$1:$A$6)),ROW())),"")

其他欄位中的公式類似：

E1:

=IFERROR(INDEX($B$1:$B$6,SMALL(IF(ISERROR(MATCH($B$1:$B$6,$A$1:$A$6,0))*ISERROR(MATCH($B$1:$B$6,$C$1:$C$6,0)),ROW($B$1:$B$6)),ROW())),"")

F1：

=IFERROR(INDEX($C$1:$C$6,SMALL(IF(ISERROR(MATCH($C$1:$C$6,$A$1:$A$6,0))*ISERROR(MATCH($C$1:$C$6,$B$1:$B$6,0)),ROW($C$1:$C$6)),ROW())),"")

從你的範例表中，我得到這些：

在此輸入影像描述

如果您的公式從與第一行不同的行開始，則需要對公式進行一些更改，因為它使用的行ROW()取決於公式所在的行。

†注意：若要使用公式，您必須按住Ctrl+ Shift，然後Enter在插入公式後按 鍵。

相關內容