如何建立 Excel 名稱/值對下拉列表

Question

我有以下列

A     | B
Name  | Value
One   | 1
Two   | 2
Three | 3

在 C 列中，我想要一個驗證下拉列表，其中顯示名稱和值的串聯（即一 - 1、二 - 2 等）。當使用者進行選擇（即“二 - 2”）時，只有“值”列中的資料才會填入儲存格（即“2”）。

我如何完成這個壯舉？

Answer 1

數據如下：

將以下 VBA 巨集放入標準模組中並執行它：

Sub DV_Maker()
   Dim i As Long
   Dim s As String

   For i = 2 To 4
      s = s & "," & Cells(i, 1) & " - " & Cells(i, 2)
   Next i
   s = Mid(s, 2)

   With Range("C2:C4").Validation
   .Delete
           .Add Type:=xlValidateList, AlertStyle:=xlValidAlertStop, Operator:= _
             xlBetween, Formula1:=s
           .IgnoreBlank = True
           .InCellDropdown = True
           .InputTitle = ""
           .ErrorTitle = ""
           .InputMessage = ""
           .ErrorMessage = ""
           .ShowInput = True
           .ShowError = False
   End With
End Sub

它將為單元格設定資料驗證C2,C3， 和C4。然後將此事件巨集放置在工作表程式碼區域中：

Private Sub Worksheet_Change(ByVal Target As Range)
   Dim rng As Range
   Set rng = Range("S2:C4")

   If Intersect(Target, rng) Is Nothing Then Exit Sub
   Application.EnableEvents = False
      Target.Value = Split(Target.Value, " - ")(1)
   Application.EnableEvents = True
End Sub

輸入資料後，事件巨集將從儲存格中刪除文字。