☰

提取多部分 rar，在提取時刪除部分

tag-icon • tag-icon windows compression rar
提取多部分 rar，在提取時刪除部分

我有一個 80GB 的多部分 rar，已解壓縮。我有 5GB 的可用空間，rar 檔案的每個部分都是 2GB。

我正在尋找的是提取一個部分，刪除它，提取下一個部分，依此類推，以便在提取過程中最多使用 5 GB 以上，而不是耗盡我的所有磁碟空間。

答案1

重要的：

  • 這個腳本將要無論最終結果如何，都刪除提取完成的部分，因此，如果進程因丟失或損壞的部分而停止，您將無法重新開始
  • 打開記事本並貼上以下程式碼並另存為_unrar.vbs與您的 rar 檔案位於同一資料夾中。
  • 放UnRAR_完整_路徑,第一部分和目標資料夾，請務必保留引號。

劇本：

UnRAR_Full_Path = "c:\program files\winrar\unrar.exe"
First_Part = "YourArchiveName.part001.rar"
Target_Folder = "ExtractedFiles\"

mf_command = AddQuotes(UnRAR_Full_Path) & " x " & AddQuotes(First_Part) & " " & AddQuotes(Target_Folder)
mf_LZerosSplit = Split(First_Part, ".")
mf_LZerosPart = Mid(mf_LZerosSplit(UBound(mf_LZerosSplit)-1), 5)
If UBound(mf_LZerosSplit) > 3 Then
    WScript.Echo ("Too Lazy to deal with names the contains dots, only 2 are allowed. one before 'part' and one before 'rar'")
    WScript.Quit 1
End If
mf_LZ_UnderTen = ""
mf_LZ_UnderHundred = ""
mf_LZ_UnderThousand = ""

If Len(mf_LZerosPart) = 2 Then
    mf_LZ_UnderTen = "0"

ElseIf Len(mf_LZerosPart) = 3 Then
    mf_LZ_UnderTen = "00"
    mf_LZ_UnderHundred = "0"

ElseIf Len(mf_LZerosPart) = 4 Then
    mf_LZ_UnderTen = "000"
    mf_LZ_UnderHundred = "00"
    mf_LZ_UnderThousand = "0"
End If 
Set objShell = CreateObject("WScript.Shell")
Set objWshScriptExec = objShell.Exec(mf_command)
Set objStdOut = objWshScriptExec.StdOut

While Not objStdOut.AtEndOfStream
    strLine = objStdOut.ReadLine

    'WScript.Echo (strLine)

        If InStr(strLine,"Extracting from") Then
            mf_filename = Mid(strLine, 17)
            mf_partnameSplit = Split(mf_filename, ".")
            mf_partname = mf_partnameSplit(1)
            mf_partnumber = Mid(mf_partname , 5)
            If mf_partnumber > 1 Then
                mf_numtodel = mf_partnumber-1
                mf_LeadingZeros = ""
                If mf_numtodel < 10 Then
                    mf_LeadingZeros = mf_LZ_UnderTen
                ElseIf mf_numtodel < 100  Then
                    mf_LeadingZeros = mf_LZ_UnderHundred
                ElseIf mf_numtodel < 1000  Then
                    mf_LeadingZeros = mf_LZ_UnderThousand
                End If
                mf_filetodel = mf_partnameSplit(0) & ".part" & mf_LeadingZeros & mf_numtodel & ".rar"

                'WScript.Echo ("NOW DELETING: " & mf_filetodel)

                Set obj = CreateObject("Scripting.FileSystemObject")
                obj.DeleteFile(mf_filetodel)
            End If
        ElseIf InStr(strLine,"All OK") Then
            WScript.Echo ("looks like All Ok, Delete the Last part and Have a nice day :)")
        End If
Wend

Function AddQuotes(strInput)
    AddQuotes = Chr(34) & strInput & Chr(34)
End Function

選項一：沉默的

跑過_unrar.vbs按兩下文件

選項二：受到推崇的

去除'從一開始

'WScript.Echo (strLine)

'WScript.Echo ("Deleting: " & mf_filetodel)

打開cmd，直接進入您的資料夾並輸入“cscript_unrar.vbs”

  • 使用WScript.Echo沒有腳本會彈出太多煩人的訊息框

該腳本透過讀取 UnRAR.exe 的標準輸出來運作。

編輯

改進了腳本，以自動處理任何名稱結構和任意數量的部件（最多 9999 個部件）。並使用不含前導零的遺留檔案。

相關內容