Excel 公式-基於查看兩個單獨值（或/或）的回傳值

Question

我使用這個公式返回下表中的值：

=IF(ISNA(VLOOKUP(A2,USUB,1,FALSE)),"No Fruit Found",VLOOKUP(A2,USUB,2,FALSE))

USB表有這樣的資料：

Fruit          Fruit Code   FruitID Location          CITY
Apple             APP          A    SEATTLE,WA          SEATTLE
Bananas           BAN          B    MODESTO,CA          MODESTO
Cherry            CHER         C    CHARLESTON,SC       CHARLESTON
Blackberrires     BLCKB        D    VICKSBURG,VA        VICKSBURG
Blueberries       BLUB         E    SAN DIEGO,CA        SAN DIEGO
Cantaloupe        CANT         F    GULF SHORES, AL     GULF SHORES
Grapes            GRP          G    NAPA VALLEY,CA      NAPA VALLEY
Peach             PCH          H    ATLANTA, GA         ATLANTA
Grapefruit        GRPFRT       I    FT LAUDERDALE, FL   FT LAUDERDALE
Pomegranate       POM          J    HONOLULU, HI        HONOLULU
Kiwi              KIW          K    SALEM, OR           SALEM

---

我將使用什麼公式先查看 Fruit (USUB,1)，然後查看 Location (USUB,4)，並根據公式中的條件傳回 Fruit Code (USUB,2) 值？

Answer 1

我很少建議使用數據獲取函數，但這是一個完美的例子，說明何時可以充分利用它。設定和使用見下圖

公式為：

=DGET(USUB,"Fruit Code",$A$1:$B$2)

它甚至還有一個額外的好處，如果您不輸入位置，它只會找到該水果的代碼。

要捕獲沒有匹配的水果和位置組合的情況，請參見下文：

=IFERROR(DGET(USUB,"Fruit Code",$A$1:$B$2),"Not found")

Answer 2

您可以使用具有多個條件的索引/匹配，以數組形式輸入（其中CTRL+SHIFT+ENTER：

=INDEX($C$2:$C$13,MATCH(H3&I3,$B$2:$B$13&$E$2:$E$13,0))

（根據需要進行調整）

因此，我能夠使用水果代碼和位置來返回 ID。該公式正確解析為J。這就是你想要的嗎？您基本上只需將Match()條件與連結起來&，然後將它們與 相符的範圍與 連結起來&，然後作為陣列輸入。

Answer 3

這將首先查看是否有重複項，如果沒有，無論輸入的位置是什麼，它都會傳回正確的 ID。

如果有多個水果，它會尋找該位置以找到匹配的水果。

如果在任何一種情況下都找不到匹配項；要么水果不存在，要么水果和位置的組合，當有多個水果時是不正確的。

=IF(COUNTIF(A:A,H2)>1,IFERROR(INDEX($C$2:$C$13,MATCH(1,INDEX(($D$2:$D$13=I2)*($A$2:$A$13=H2),),0)),"Multiple fruits but Location is wrong"),IFERROR(INDEX(C:C,MATCH(H2,A:A,0)),"Not Found"))

對於表格的引用，請使用：

=IF(COUNTIF(USUB[Fruit],H2)>1,IFERROR(INDEX(USUB[FruitID],MATCH(1,INDEX((USUB[Location]=I2)*(USUB[Fruit]=H2),),0)),"Multiple fruits but Location is wrong"),IFERROR(INDEX(USUB[FruitID],MATCH(H2,USUB[Fruit],0)),"Not Found"))