☰

微軟Excel，一個單元格中的多個公式

tag-icon • tag-icon microsoft-excel
微軟Excel，一個單元格中的多個公式

我需要一些有關將多個公式放入一個單元格中的幫助。

如果我在 g11 中輸入 1 我希望它使用下面的公式 =if(H11="","",I11/(230*H11))

如果我在 g11 中輸入 3 我希望它使用以下公式 =if(H11="","",I11/(sqrt(3)*400*H11*(E11/100)))

先致謝

答案1

您也可以使用相同的 IF 函數來測試 G11 細胞：（在單行中使用此公式）

=if(G11=1,  
    if(H11="","",I11/(230*H11)), 
    if(G11=3, 
            if(H11="","",I11/(sqrt(3)*400*H11*(E11/100))),
            ""
      )
   )

=if(G11=1,測試其值是否
        if(H11="","",I11/(230*H11)),為 1 True 條件運行公式 1
        if(G11=3,如果為 False，則測試其值 3
              if(H11="","",I11/(sqrt(3)*400*H11*(E11/100))),如果 G11 為 3 然後運行第二個公式
              ""if G11 沒有其他操作
      )close if(G11=3,,)
)close if (G11=1 ,,)

答案2

怎麼樣

 =IF(G11=1,IF(H11="","",I11/(230*H11)),IF( G11=3,IF(H11="","",I11/(SQRT(3)*400*H11*(E11/100))),""))

答案3

您肯定已經注意到您的兩個（可選）公式是非常相似的：

=if(H11="","",I11/(230        *H11          ))
 ↕↕↕↕↕↕↕↕↕↕↕↕↕↕↕↕↕↕           ↕↕↕↕          ↕↕
=if(H11="","",I11/(sqrt(3)*400*H11*(E11/100)))

您可以重新排列第二個公式以簡化它並增加相似度：

 400*H11*(E11/100)
=400*(E11/100)*H11
=(400*E11/100)*H11
=(E11*400/100)*H11
=E11*(400/100)*H11
=E11 *   4   * H11
=4*E11*H11

所以你的第二個公式減少為

=if(H11="","",I11/(sqrt(3)*4*E11*H11))

我們可以利用這種相似性來簡化整個公式（在其他幾個答案中已經給出）

=if(H11="","",I11/(IF(G11=1,230,IF(G11=3,sqrt(3)*4*E11,0))*H11))

請注意，如果G11是 1 或 3 以外的任何值，則會明確除以 0，這將導致錯誤。如果這對您來說是個問題，請不要使用此答案。

相關內容