☰

如果我在儲存格 A8 中輸入字母 TL，有沒有辦法將該儲存格和該行中的多個其他儲存格變成藍色？

tag-icon • tag-icon microsoft-excel microsoft-excel-2013
如果我在儲存格 A8 中輸入字母 TL，有沒有辦法將該儲存格和該行中的多個其他儲存格變成藍色？

如果我在儲存格 A8 中輸入字母 TL，有沒有辦法將該儲存格和該行中的多個其他儲存格變成藍色？有沒有辦法有多種字母/顏色變化？

我有 8 個兩個字母的組合，對應 8 種顏色。例如： TS=淺藍色 TC=中藍色 TL=深藍色 DD=黑色 RS=淺綠色 RC=中綠色 RL=深綠色 LT=棕色 我想將這些字母組合之一輸入 M8 並有列第8行中的B、C、E、F、K-AM轉成對應的顏色。有沒有辦法做到這一點？

答案1

如果我在儲存格中輸入字母 TLA8...將這些字母組合之一輸入到M8& 第 8 行有列 B、C、E、F、K-AM ...

你的敘述令人困惑。此代碼適用於 M8。

調整工作表名稱和您想要的顏色的 RGB 參數，然後執行此程式碼。

Option Explicit

Sub addCFRs()

    Dim i As Long, rng As Range, arr1 As Variant, arr2 As Variant

    arr1 = Array("TS", "TC", "TL", "DD", "RS", "RC", "RL", "LT")
    arr2 = Array(RGB(0, 0, 255), RGB(0, 0, 128), RGB(0, 0, 64), RGB(0, 0, 0), _
                 RGB(0, 255, 0), RGB(0, 128, 0), RGB(0, 64, 0), RGB(0, 0, 0))

    With Worksheets("sheet6")

        Set rng = Intersect(.Range("B:C, E:F, K:AM"), .Range("8:8"))

        With rng

            .FormatConditions.Delete

            For i = LBound(arr1) To UBound(arr1)

                .FormatConditions.Add Type:=xlExpression, Formula1:="=$M8=" & Chr(34) & arr1(i) & Chr(34)
                .FormatConditions(.FormatConditions.Count).Interior.Color = arr2(i)

            Next i

        End With

    End With

End Sub

除了棕色之外，大多數 RGB 都有點接近您想要的顏色；我不知道RGB是什麼顏色組成的。

答案2

這可以使用條件格式來完成。
每種顏色都需要一個單獨的配方。

  • 在第 8 行中要變更顏色的儲存格（您可以使用Ctrl+ 按一下來選取單獨的儲存格）
  • 轉到“條件格式”並選擇“新規則”
  • 選擇“使用公式確定要設定格式的儲存格”
  • 在規則描述中輸入=$M8="TL"
  • 點擊“格式”並選擇頂部的“填充”選項卡
  • 為程式碼選擇正確的顏色
  • 按一下“確定”，然後再次按一下“確定”。
    第 8 行全部完成。

如果您希望它執行更多行，請轉到“條件格式”並選擇“管理規則”。

選擇“適用於”框右側的圖標，然後突出顯示要更改顏色的所有區域。同樣，您可以使用Ctrl選擇單獨的區域。如果需要，您可以選擇整個列，但這會減慢工作表的速度。

設定完成後，您可以對其他顏色代碼重複此過程，只需將TL公式替換為您想要使用的代碼即可。

相關內容