☰

開啟特定應用程式視窗的熱鍵 (MS Teams)

tag-icon • tag-icon windows-10 hotkeys microsoft-teams
開啟特定應用程式視窗的熱鍵 (MS Teams)

有沒有辦法在 Windows 10 中設定熱鍵來取消最小化特定的應用程式視窗？我想要執行此操作的應用程式（MS Teams）已經在背景運行。

我確實給它分配了一個快捷鍵

在此輸入影像描述

但由於某種原因，它的運行速度非常慢 - 將視窗打開需要大約 10 秒，而如果我單擊任務欄中的圖標，它是即時的 - 所以它不可能是「緩慢的 PC 滯後」。

答案1

要取消最小化特定應用程式的窗口，您可以使用免費的 自動熱鍵。

以下範例腳本使用F12key 取消最小化視窗 notepad.exe：

F12::WinActivate, ahk_exe notepad.exe

AutoHotKey 用途廣泛，可對上述指令進行多種修改。

安裝完AutoHotKey後，將上述文字放入一個.ahk檔案中，雙擊進行測試。您可以透過右鍵單擊托盤欄中的綠色 H 圖示並選擇「退出」來停止腳本。若要使其在登入時執行，請將其放置在位於 的啟動群組中 C:\Users\USER-NAME\AppData\Roaming\Microsoft\Windows\Start Menu\Programs\Startup。

有用的 AutoHotkey 文件：

答案2

如果您想啟動 Microsoft Teams 主窗口，您也可以看看團隊。它還提供編譯版本，因此您無需安裝 AutoHotkey 即可運行它。

執行此操作的主要程式碼如下所示：

Teams_GetMainWindow(){
; See implementation explanations here: https://tdalon.blogspot.com/get-teams-window-ahk
; Syntax: hWnd := Teams_GetMainWindow()

WinGet, WinCount, Count, ahk_exe Teams.exe

If (WinCount = 0)
    GoTo, StartTeams

If (WinCount = 1) {
    TeamsMainWinId := WinExist("ahk_exe Teams.exe")
    return TeamsMainWinId
}

; Get main window via Acc Window Object Name
WinGet, id, List,ahk_exe Teams.exe
Loop, %id%
{
    hWnd := id%A_Index%
    oAcc := Acc_Get("Object","4",0,"ahk_id " hWnd)
    sName := oAcc.accName(0)
    If RegExMatch(sName,".* \| Microsoft Teams, Main Window$") {
        return hWnd
    }
}

; Fallback solution with minimize all window and run exe
If WinActive("ahk_exe Teams.exe") {
    GroupAdd, TeamsGroup, ahk_exe Teams.exe
    WinMinimize, ahk_group  TeamsGroup
} 

StartTeams: 
fTeamsExe = C:\Users\%A_UserName%\AppData\Local\Microsoft\Teams\current\Teams.exe
If !FileExist(fTeamsExe) {
    return
}

Run, %fTeamsExe%
WinWaitActive, ahk_exe Teams.exe
TeamsMainWinId := WinExist("A")
PowerTools_RegWrite("TeamsMainWinId",TeamsMainWinId)
return TeamsMainWinId

} ; eofun

要旨：https://gist.github.com/tdalon/84d9caea0368ab0420b81363c2048705

要做你想做的事，只需撥打電話

WinId := Teams_GetMainWindow()
WinActivate, ahk_id %WinId%

您可以將其綁定到任何熱鍵，例如 F12

F12::
WinId := Teams_GetMainWindow()
WinActivate, ahk_id %WinId% 
return

相關內容