從 ifconfig 中提取介面名稱、硬體位址和 IP 位址（必須使用 ifconfig 而不是 ip 命令）

Question 1

awk 'BEGIN { OFS="\t" }; # use tab for output separator

     ! /^ / {   # line doesnt begin with a space, must be an interface line, extract it
       i=gensub(/:$/,"",1,$1)
       mac[i]=$5;     # this will either be a HWAddr or empty
       ifaces[i]=1
     };

     /^ +inet/ { ip[i] = ip[i] " " gensub(/addr:/,"",1,$2) };

     /^ +ether/ { mac[i]=$2};  # this will only match if there WASNT a HWAddr on the iface line

     END {
       for (i in ifaces) {
         sub(/^ +/,"",ip[i]); # remove unwanted space from beginning of ip addresses
         #if (ip[i]  == "") ip[i]  = "--"; #optional
         #if (mac[i] == "") mac[i] = "--"; #optional
         print i, ip[i], mac[i]
       }
     }' filename | sort

（或只是透過管道輸入ifconfig而不是給它一個輸入檔名）

此 awk 腳本可以處理任一ifconfig輸出變體，並輸出三個製表符分隔的欄位：介面名稱、IP 位址和 MAC 位址。

如果第二個欄位中有多個 IP 位址，則它們之間會以空格分隔。

針對 input1 運行並透過管道傳輸到時的輸出sort：

eno16780032     192.168.0.1     00:50:56:00:00:00
eno33559296     192.168.0.2     00:50:56:00:00:01
lo      127.0.0.1

針對 input2 運行並透過管道傳輸到時的輸出sort：

bond0:0 192.168.0.1     00:50:56:00:00:00
bond0   192.168.0.1     00:50:56:00:00:00
eth0            00:50:56:00:00:00
eth1            00:50:56:00:00:00
lo      127.0.0.1

注意：您要求的輸出將 192.168.0.2 作為 bond0:0 的 IP 位址，但您的範例資料具有 192.168.0.1，與介面相同bond0。

如果取消註解腳本中的「可選」行，它將確保始終有 3 個製表符分隔的輸出字段，即使 IP 位址或 MAC 位址字段為空。

輸出如下：

eno16780032     192.168.0.1     00:50:56:00:00:00
eno33559296     192.168.0.2     00:50:56:00:00:01
lo      127.0.0.1       --

和

bond0:0 192.168.0.1     00:50:56:00:00:00
bond0   192.168.0.1     00:50:56:00:00:00
eth0    --      00:50:56:00:00:00
eth1    --      00:50:56:00:00:00
lo      127.0.0.1       --

補充評論：

它是一個錯誤忽略該ip命令。它多年來一直是 Linux 上的標準，許多向介面添加輔助/備用/「別名」IP 位址的程式都會使用它。以這種方式新增至介面的輔助 IP 位址將僅有的顯示為，運行ip addr show時它們不會顯示。ifconfig

ifconfig應該只被視為遺留，至少在 Linux 上是如此。

Answer

awk 'BEGIN { OFS="\t" }; # use tab for output separator

     ! /^ / {   # line doesnt begin with a space, must be an interface line, extract it
       i=gensub(/:$/,"",1,$1)
       mac[i]=$5;     # this will either be a HWAddr or empty
       ifaces[i]=1
     };

     /^ +inet/ { ip[i] = ip[i] " " gensub(/addr:/,"",1,$2) };

     /^ +ether/ { mac[i]=$2};  # this will only match if there WASNT a HWAddr on the iface line

     END {
       for (i in ifaces) {
         sub(/^ +/,"",ip[i]); # remove unwanted space from beginning of ip addresses
         #if (ip[i]  == "") ip[i]  = "--"; #optional
         #if (mac[i] == "") mac[i] = "--"; #optional
         print i, ip[i], mac[i]
       }
     }' filename | sort