☰

使用 Active Directory 欄位在 Exchange 2003 中實作簽章原則

tag-icon • tag-icon active-directory exchange outlook
使用 Active Directory 欄位在 Exchange 2003 中實作簽章原則

我們的組織決定需要根據所有使用者的姓名、職位、聯絡資訊和辦公地點（所有這些都儲存在 Active Directory 中）為所有使用者提供一個標準簽名區塊。

有沒有人找到一個基於 Active Directory 欄位自動產生 Outlook/Exchange 2003 簽章的巧妙解決方案？

答案1

我是它的長期客戶和粉絲Exclaimer 郵件實用程式。

它位於您的 Exchange 伺服器上，並具有許多可自訂的規則，用於確定是否套用固定模式。我將其添加到外部發送的所有電子郵件的頂部，我們的公司徽標，以及底部的人員姓名、職位和各種電話號碼 - 全部從 Active Directory 中提取。

我只使用過一次支持，但他們非常友好、知識淵博，並且很快就解決了我的問題。

答案2

我寫的劇本非常幸運。它將各種 AD 欄位寫入不可見的 Word 文檔，然後將其複製到 Outlook 2007 中作為預設簽名和回覆簽署。

我不再讓它在每次登入時自動運行。我很少會在使用者首次登入電腦時遇到問題，即如果不執行精靈就無法開啟 Outlook。截至目前，它只是一個 GPO，它只是將一個名為“重置電子郵件簽名”的快捷方式推送到用戶桌面。這也允許用戶擁有非預設簽名，而不會每次都被覆蓋。

On Error Resume Next

Set objSysInfo = CreateObject("ADSystemInfo")

strUser = objSysInfo.UserName
Set objUser = GetObject("LDAP://" & strUser)

strName = objUser.FullName
strTitle = objUser.Title
strDepartment = objUser.Department
strCompany = objUser.Company
strPhone = objUser.telephoneNumber
strFax = objUser.faxNumber

strStreet = objUser.StreetAddress
strCity = objUser.L
strState = objUser.St
strPOBox = objUser.postalCode

strFirstName = objUser.givenName
strInitials = objUser.initials
strLastName = objUser.sn
If strInitials = "" Then
    strFullName = strFirstName & " " & strLastName
Else
    strFullName = strFirstName & " " & strInitials & ". " & strLastName
End If

Set objWord = CreateObject("Word.Application")

Set objDoc = objWord.Documents.Add()
Set objSelection = objWord.Selection
objSelection.Style = "No Spacing" 
objSelection.Font.Name = "Calibri"
objSelection.Font.Size = "11"

Set objEmailOptions = objWord.EmailOptions
Set objSignatureObject = objEmailOptions.EmailSignature

Set objSignatureEntries = objSignatureObject.EmailSignatureEntries

objSelection.TypeParagraph()
objSelection.TypeText "Sincerely,"
objSelection.TypeParagraph()
objSelection.TypeParagraph()
objSelection.TypeText "ORGANIZATION NAME"
objSelection.TypeParagraph()
objSelection.TypeParagraph()
objSelection.TypeText strFullName & ", " & strTitle
'objSelection.TypeText strName & ", " & strTitle
objSelection.TypeParagraph()
objSelection.TypeParagraph()
objSelection.TypeText strStreet
objSelection.TypeParagraph()
objSelection.TypeText strCity & ", " & strState & " " & strPOBox
objSelection.TypeParagraph()
objSelection.TypeText "Desk: " & strPhone
objSelection.TypeParagraph()
objSelection.TypeText "Fax:    " & strFax
objSelection.TypeParagraph()

'Hyperlink below
objDoc.Hyperlinks.Add objSelection.Range, "www.yoursitename.com", "", "", "www.yoursitename.com", ""

objSelection.TypeParagraph()
objSelection.TypeParagraph()

'Picture below
Set objShape = objSelection.InlineShapes.AddPicture("\\fileserver\path\to\image.BMP")

Set objSelection = objDoc.Range()

objSignatureEntries.Add "AD Signature", objSelection
objSignatureObject.NewMessageSignature = "AD Signature"
objSignatureObject.ReplyMessageSignature = "AD Signature"

objDoc.Saved = True
objWord.Quit

如果您有任何疑問，請告訴我！

相關內容