☰

Office 2010 無人安裝後靜默激活

tag-icon • tag-icon unattended microsoft-office-2010 microsoft-office
Office 2010 無人安裝後靜默激活

我已使用 OCT 建立了 Office 2010 的無人值守安裝。我們使用 MAK 而不是 KMS（不是我的決定）。有沒有辦法在安裝後啟動Office 2010？即使在安裝過程中設定了密鑰，它也不會啟動。

我不希望提示用戶激活，因為這將在實驗室環境中進行。

答案1

如果有人想知道 - Office 在 office14 目錄中安裝 OSPP.VBS，並且可以處理 Office 啟動等。

c:\windows\system32\cscript C:\"Program Files (x86)\Microsoft Office\Office14\OSPP.VBS" /act在 OCT 中，我將其設定為在安裝後運行。

之後所有辦公產品均啟動。我先靜默安裝 Visio、Project，然後安裝 Office，然後讓 Office 開始激活，所有三個產品都會立即啟動。

答案2

不要在這篇文章中混淆視聽，但我在 OCT 中使用以下命令進行了設定：
[WindowsFolder]\system32\cscript [INSTALLLOCATION]\OSPP.VBS
參數為 /act

以防萬一其他人需要該資訊。羅斯

答案3

只需將此批次放入您的後系統準備腳本中，就可以解決您的問題。已在 32 位元和 64 位元系統以及不同作業系統上進行測試。

也許有人可以 vbs 這個或其他什麼。

啟動屬性.cmd

REM CUSTOMER NAME HERE
REM DATE LAST MODIFIED

set _win7vlk=XXXXX-8FFQX-YYYYY-33XHT-ZZZZZ
set _2010vlk=YYYYY-YYYYY-WQGB6-KW8P8-XXXXX

REM Use current working dir
cd /d "%~dp0"

if not defined _win7vlk if not defined _2010vlk goto :nokey

echo Checking for internet connectivity needed to activate
echo This screen will not progress until internet is established
echo If you are using firewall please disable the firewall temporarily

:LOOP
PING -n 3 google.com|find "TTL" >NUL
IF NOT ERRORLEVEL 1 goto :ENDLOOP
IF     ERRORLEVEL 1 goto :LOOP
:ENDLOOP
echo Internet Detected

echo Change the time
net time \\LANMACHINEWITHCORRECTTIME /set /y

echo Prompt to activate Windows 7 if needed
if exist "%windir%\system32\slmgr.vbs" FOR /F "tokens=5" %%a in ('cscript "%windir%\system32\slmgr.vbs" -xpr') do (set _act=%%a)
if "%_act%" neq "activated." if defined _win7vlk (
    cscript "%windir%\system32\slmgr.vbs" -ipk %_win7vlk%
    cscript "%windir%\system32\slmgr.vbs" -ato
    )

echo Prompt to activate Office 2010 if needed
if exist "%PROGRAMFILES%\Microsoft Office\Office14\WINWORD.exe" set _offver=%PROGRAMFILES%
if exist "%PROGRAMFILES% (x86)\Microsoft Office\Office14\WINWORD.exe" set _offver=%PROGRAMFILES% (x86)

if defined _offver if defined _2010vlk (FOR /F "tokens=3* delims=: " %%a in ('cscript "%_offver%\Microsoft Office\Office14\OSPP.VBS" /dstatus') do (
    if "%%a" == "---OOB_GRACE---" (cscript "%_offver%\Microsoft Office\Office14\OSPP.VBS" /inpkey:%_2010vlk%
                    cscript "%_offver%\Microsoft Office\Office14\OSPP.VBS" /act)
    if "%%a" == "---OOT_GRACE---" (cscript "%_offver%\Microsoft Office\Office14\OSPP.VBS" /inpkey:%_2010vlk%
                    cscript "%_offver%\Microsoft Office\Office14\OSPP.VBS" /act)
    if "%%a" == "---NOTIFICATIONS---" (cscript "%_offver%\Microsoft Office\Office14\OSPP.VBS" /inpkey:%_2010vlk%
                    cscript "%_offver%\Microsoft Office\Office14\OSPP.VBS" /act)
    ))



:nokey

答案4

您也可以透過設定 AUTO_ACTIVATE 屬性值在安裝 MAK 金鑰時啟動 Office 2010。去做這個，按著這些次序:

  1. 在 OCT 中，選擇修改設定屬性在左側窗格中，然後按一下添加在右窗格中。

  2. 在裡面添加財產價值對話框中，在姓名框、類型自動啟用。請注意，屬性名稱必須大寫。

  3. 在裡面價值框、類型1，然後按一下好的。

相關內容