☰

如何在 AIX 中取得檔案擁有者而不需要修改 ls 輸出？

tag-icon • tag-icon files aix stat
如何在 AIX 中取得檔案擁有者而不需要修改 ls 輸出？

我怎樣才能可靠地取得 AIX 中文件的擁有者？透過可靠，我不想解析ls.在 Linux 上，我只會執行 a stat --printf=%U foo，但我正在 AIX 6.1 和 7.1 上工作。我知道我可以這樣做，但由於AIX 上istat沒有選項，我仍然必須使用 和 來處理輸出，因此不太理想。換句話說，如何僅使用 AIX 的核心實用程式來模擬 Linux？--printfistatgrepawkstat --printf=%U foo

答案1

這是我不久前編寫的腳本，目的是為了在 AIX 中獲得類似 stat(1) 的實用程式。剛剛加%U！我發現使用 -c 選項更有用，它的行為與 --printf 略有不同。包括一個方便的 perl 統計數組的本機副本作為註解區塊。

#!/usr/bin/env perl -w
# emulate GNU coreutils stat command in a limited way
# -- only implemented a subset of the stat() options

use strict;
use Getopt::Std;
our $opt_c;

getopts('c:') or die "Usage: $0 [ -c (%n %i %u %g %s %U %X %Y %Z) ] file ...";
# default format is empty (not useful, but avoids 'undef' errors later)
$opt_c |= '';

for (@ARGV) {
  my @s = stat;
  next unless @s; # silently fail on to the next file
  my $p = $opt_c; # make a copy of the format string to mangle for each file

  # mangle and print
  $p =~ s/%n/$_/g;
  $p =~ s/%i/$s[1]/g;
  $p =~ s/%u/$s[4]/g;
  $p =~ s/%g/$s[5]/g;
  $p =~ s/%s/$s[7]/g;
  $p =~ s/%U/getpwuid($s[4])/eg;
  $p =~ s/%X/$s[8]/g;
  $p =~ s/%Y/$s[9]/g;
  $p =~ s/%Z/$s[10]/g;
  print "$p\n";

  #                 0 dev      device number of filesystem
  #                 1 ino      inode number
  #                 2 mode     file mode  (type and permissions)
  #                 3 nlink    number of (hard) links to the file
  #                 4 uid      numeric user ID of file's owner
  #                 5 gid      numeric group ID of file's owner
  #                 6 rdev     the device identifier (special files only)
  #                 7 size     total size of file, in bytes
  #                 8 atime    last access time in seconds since the epoch
  #                 9 mtime    last modify time in seconds since the epoch
  #                10 ctime    inode change time in seconds since the epoch (*)
  #                11 blksize  preferred block size for file system I/O
  #                12 blocks   actual number of blocks allocated

}

相關內容