☰

すべての PowerPoint スライドの言語を一度に変更するにはどうすればよいですか?

tag-icon • tag-icon windows microsoft-office microsoft-powerpoint microsoft-powerpoint-2010
すべての PowerPoint スライドの言語を一度に変更するにはどうすればよいですか?

Powerpoint のすべてのスライドの校正言語を変更したいです。言語設定メニューから言語を設定しようとしましたが、新しい Powerpoint に対してのみ変更されます。

答え1

言語を変更するには全体PowerPointを簡単に開くには、ビュータブをクリックして概要ビュー。

今すぐ押してください

  • Ctrl+Aすべてを選択します。
  • ツール→言語→ 設定する言語を選択します。

同様に、すべてを選択した状態で、フォントや色などの他の項目を変更できます。もちろん、多くの場合、スライド マスターを変更した方がよいのですが、多くの編集者が作成したプレゼンテーションには、基礎となるマスターから逸脱した「ハード」な書式設定が多数ある場合があり、一貫性を保つためにリセットする必要があります。個々のスライドをマスター スタイルにリセットすることもできますが、これによりプレースホルダーも移動する可能性があり、状況によっては望ましくない場合があります。

パワーポイント2013

  • ビュー→概要Ctrl→ +ですべてのスライド（左側のメニュー内）を選択しますA。
  • レビュー→言語→校正言語の設定...→ 設定する言語を選択します。

私の場合 - PowerPoint再起動必要だった。おそらく私も変更したからだろう編集言語:

  • レビュー→言語→校正言語の設定...→言語設定→編集言語を選択。

答え2

使用パワーポイント2010アウトラインメニューを開きました -

アウトラインタブ

すべてのテキストを選択し（Ctrl+A）、言語メニューを開いて校正言語を設定しました

言語オプション

そしてそれはうまくいきました！

言語メニューは、[レビュー] リボン タブにあります ([スライド ショー] タブの後にあり、スクリーンショットには表示されていません)。

答え3

私は改善しましたイニゴの答えすべての項目を目的の言語に変更する再帰バージョンを提供します。

このバージョンでは、グループ タイプである各図形を再帰的に調査します。いくつかの実験では、msoGroupと がmsoSmartArtグループ タイプであることが示唆されています。テキスト オブジェクトを保持できる他のタイプの図形が見つかった場合は、そのリストに自由に追加してください。

Sub ChangeProofingLanguageToEnglish()
    Dim j As Long, k As Long
    Dim languageID As MsoLanguageID

    'Set this to your preferred language
    languageID = msoLanguageIDEnglishUK

    For j = 1 To ActivePresentation.Slides.Count
        For k = 1 To ActivePresentation.Slides(j).Shapes.Count
            ChangeAllSubShapes ActivePresentation.Slides(j).Shapes(k), _
              languageID
        Next k
    Next j
End Sub


Sub ChangeAllSubShapes(targetShape As shape, languageID As MsoLanguageID)
    Dim i As Long

    If targetShape.HasTextFrame Then
        targetShape.TextFrame.TextRange.languageID = languageID
    End If

    Select Case targetShape.Type
        Case msoGroup, msoSmartArt
            For i = 1 To targetShape.GroupItems.Count
                ChangeAllSubShapes targetShape.GroupItems.Item(i), languageID
            Next i
    End Select
End Sub

答え4

Inigo、Duncan、Maria、DomDev の回答に基づくと、これは現在も将来も、図形、表、グループ、SmartArt で機能します。

Sub ChangeProofingLanguageToFrench()
    Dim j, k As Integer
    Dim languageID As MsoLanguageID

    'Set this to your preferred language
    languageID = msoLanguageIDFrench

    'Loop all the slides in the document, and change the language
    For j = 1 To ActivePresentation.Slides.Count
        For k = 1 To ActivePresentation.Slides(j).Shapes.Count
            ChangeAllSubShapes ActivePresentation.Slides(j).Shapes(k), languageID
        Next k
    Next j

    'Loop all the master slides, and change the language
    For j = 1 To ActivePresentation.SlideMaster.CustomLayouts.Count
        For k = 1 To ActivePresentation.SlideMaster.CustomLayouts(j).Shapes.Count
            ChangeAllSubShapes ActivePresentation.SlideMaster.CustomLayouts(j).Shapes(k), languageID
        Next k
    Next j

    'Change the default presentation language, so that all new slides respect the new language
    ActivePresentation.DefaultLanguageID = languageID
End Sub

Sub ChangeAllSubShapes(targetShape As Shape, languageID As MsoLanguageID)
    Dim i As Integer, r As Integer, c As Integer

    If targetShape.HasTextFrame Then
        targetShape.TextFrame.TextRange.languageID = languageID
    End If

    If targetShape.HasTable Then
        For r = 1 To targetShape.Table.Rows.Count
            For c = 1 To targetShape.Table.Columns.Count
                targetShape.Table.Cell(r, c).Shape.TextFrame.TextRange.languageID = languageID
            Next
        Next
    End If

    Select Case targetShape.Type
        Case msoGroup, msoSmartArt
            For i = 1 To targetShape.GroupItems.Count
                ChangeAllSubShapes targetShape.GroupItems.Item(i), languageID
            Next i
    End Select
End Sub

関連情報