ウィンドウを常に他のウィンドウの下に維持する Windows 7 の機能またはフリーウェア

Question 1

昔、Windows には X-Mouse と呼ばれる PowerToy (後に TweakUI に) がありました。これは、特に、古いスタイルの X の「フォーカスはマウスに従います」をサポートしていました。この「フォーカス」と「フォアグラウンド」は同じものではありませんでした。これはもうメンテナンスされていないと思います (最後に見たのは WinXP でした)。

あまり使っていないが、無料のWindowsスクリプトツールオートIT短いスクリプトで必要なことを行うことができます:

#include <WinAPI.au3>
#include <Constants.au3>
#include <WindowsConstants.au3>
#include <MenuConstants.au3>
#include <SendMessage.au3>

Local $hWnd,$flags,$regexp

Func MyExit() 
    MsgBox(0,"Drop Window","Quitting!",2) 
    Exit 0
EndFunc

$flags = BitOr($SWP_NOMOVE,$SWP_NOSIZE,$SWP_NOACTIVATE,$SWP_ASYNCWINDOWPOS,$SWP_NOSENDCHANGING) 

;; hot key to call exit: ALT + F11
HotKeySet("!{F11}","MyExit")

;; application window title
$regexp=".*Notepad$"

;; 10 second time out on first startup, 
$hWnd = WinWait("[REGEXPTITLE:" & $regexp & "]", "", 10)
;; or wait forever
;$hWnd = WinWait("[REGEXPTITLE:" & $regexp & "]")

If ($hWnd) Then
    ;; uncomment next line to maximize window first
    ;_SendMessage($hWnd,$WM_SYSCOMMAND,$SC_MAXIMIZE)

    _WinAPI_SetWindowPos($hWnd, $HWND_BOTTOM, 0, 0, 0, 0, $flags);

    While 1
        If WinWaitActive($hWnd,"",10) Then
            _WinAPI_SetWindowPos($hWnd, $HWND_BOTTOM, 0, 0, 0, 0, $flags);
        EndIf
        ;; check for new window
        $hWnd = WinWait("[REGEXPTITLE:" & $regexp & "]","",1) 

        ;; uncomment next 3 lines to quit if no window
        ;if (NOT $hWnd) Then
        ;    MyExit()
        ;EndIf

        Sleep(250)
    Wend
Else
    MsgBox(0,"Drop Window","No window title matching /" & $regexp & "/") 
EndIf

「最上位」は WM が維持する永続的なウィンドウプロパティであり、「最下位」に相当するものはないため、少し調整する必要があります。

While ループは、アプリケーションがフォアグラウンドになるまで待機し、キーボードフォーカスを保持したままアプリケーションを再びフォアグラウンドにドロップします。モーダルポップアップがこれを妨げる場合もありますが、問題なく使用できます。スクリプトは、監視対象のプログラムが終了した後もバックグラウンドで実行され続けます。いつでも Alt+F11 で終了できます。

$regexp を「mIRC」などに一致するように変更します。上記は、一度に 1 つのウィンドウのみを確実に処理します。ウィンドウタイトル以外でウィンドウを一致させる方法については、WinWait() の AutoIT ドキュメントを参照してください。

dropwindow.au3 に保存し、「autoit3 dropwindow.au3」で実行します。

http://www.autoitscript.com/site/autoit/downloads/

Answer