☰

Outlook 2010: メッセージを読むためのデフォルトのズーム レベルを設定する

tag-icon • tag-icon microsoft-outlook microsoft-outlook-2010
Outlook 2010: メッセージを読むためのデフォルトのズーム レベルを設定する

Outlook 2010 でメッセージを開くとき (閲覧ウィンドウを使用しない場合)、Ctrl キーを押しながらマウス ホイールを上に回してメッセージを拡大できますが、メッセージを開くたびにこの操作を行う必要があります。

メッセージのデフォルトのズーム レベルを設定する方法はありますか? たとえば、各メッセージのズーム レベルをデフォルトで 150% に設定します。

それができない場合は他のメッセージを読むときにデフォルトのテキストを大きくする方法はありますか？（OSのDPI設定を変更せずに）

答え1

これは Outlook 2010 の通常の動作です。ズーム調整は保持されません。唯一の選択肢は、起動時に実行されるマクロを作成するか、ズーム制御用のアドインを使用することです。

アプリケーションの起動時にズーム レベルを設定するための VBA を追加する方法を次に示します。

  1. マクロのセキュリティを「低」に設定します。
  2. Alt+を使用してVBエディタを開きますF11
  3. Project1を展開して表示するThisOutlookSession
  4. マクロを貼り付けるThisOutlooksession
  5. ツール、参照設定でMicrosoft Wordへの参照を設定します。
  6. マクロをクリックしApplication_Startupてボタンを押すRunと、Outlook を再起動せずにマクロが起動します。
Option Explicit
Dim WithEvents objInspectors As Outlook.Inspectors
Dim WithEvents objOpenInspector As Outlook.Inspector
Dim WithEvents objMailItem As Outlook.MailItem

Private Sub Application_Startup()
Set objInspectors = Application.Inspectors
End Sub

Private Sub Application_Quit()
Set objOpenInspector = Nothing
Set objInspectors = Nothing
Set objMailItem = Nothing
End Sub

Private Sub objInspectors_NewInspector(ByVal Inspector As Inspector)
If Inspector.CurrentItem.Class = olMail Then
Set objMailItem = Inspector.CurrentItem
Set objOpenInspector = Inspector
End If
End Sub

Private Sub objOpenInspector_Close()
Set objMailItem = Nothing
End Sub

Private Sub objOpenInspector_Activate() 
Dim wdDoc As Word.Document
Set wdDoc = objOpenInspector.WordEditor
wdDoc.Windows(1).Panes(1).View.Zoom.Percentage = 150
End Sub

注: 最後から 2 番目の行は、ズーム率を設定する場所です。150希望するパーセントに変更してください。

ソース -Outlookのメールのズーム設定を調整する

答え2

というアドインを見つけましたズームインリボンにボタンを追加して、開いたすべてのメッセージのズームを保存します (いつでも変更することもできます)。唯一の欠点は、有料ツールであることです。

関連情報