Mac でシステム環境設定を切り替えるキーボードショートカットを設定できますか

Question

の例 AppleScript コード以下に示すものは、macOSカタリナそしてmacOS ビッグサー と言語と地域設定システム環境設定に設定英語（米国） — プライマリ私の場合は問題なく動作しました¹。

¹ _{必要かつ適切な設定を前提とするシステム環境設定>セキュリティとプライバシー>プライバシー必要に応じて設定/対処されています。}

例 AppleScript コード:

if running of application "System Preferences" then
    try
        tell application "System Preferences" to quit
    on error
        do shell script "killall 'System Preferences'"
    end try
    delay 0.1
end if

repeat while running of application "System Preferences" is true
    delay 0.1
end repeat

tell application "System Preferences" to ¬
    reveal anchor "Seeing_Zoom" of ¬
        pane id "com.apple.preference.universalaccess"

tell application "System Events"
    tell application process "System Preferences"
        tell pop up button 1 of group 1 of window 1
            if its value is "Split screen" then
                click
                delay 0.1
                click menu item "Picture-in-picture" of menu 1
            else if its value is "Picture-in-picture" then
                click
                delay 0.1
                click menu item "Split screen" of menu 1
            else
                click
                delay 0.1
                click menu item "Split screen" of menu 1
            end if
        end tell
    end tell
end tell

delay 0.2

tell application "System Preferences" to quit

ノート：

の例 AppleScript コード使用できるオートメーター サービス/クイックアクションを使ってAppleScriptを実行する アクション、デフォルトを置き換えるコードそれに伴って、キーボードショートカットで：システム環境設定>キーボード>ショートカット>サービス

注意：グローバルキーボードショートカット踏まないようにするのは難しいキーボードショートカットどちらか応用フォーカスがあるのはグローバルキーボードショートカット押すと、追加が必要になる場合があります応用に：システム環境設定>セキュリティとプライバシー>プライバシー

いずれかを使用する方が良いかもしれませんサードパーティアプリケーショントリガーを処理できるAppleScript スクリプトとともにキーボードショートカットを使用するよりもオートメーター サービス/クイックアクション。私が使うファストスクリプト私はその開発者とは何ら関係がなく、ただその製品に満足しているユーザーです。

の例 AppleScript コードまた、AppleScript 応用同じように。

コード通り、現在の価値のズームスタイル: ポップアップメニューのいずれかに設定されている画面を分割またはピクチャーインピクチャー切り替えます。全画面表示切り替えると画面を分割。

の例 AppleScript コード用途UI スクリプトそして、一部のUI要素画面に一瞬表示されることがありますが、この特定の使用例では、コード化されたとおりにズームスタイル: ポップアップメニュー選択肢を切り替えるときに使用します。

全体をご覧になりたい場合はインターフェースのシステム環境設定ターゲットを切り替える間ポップアップメニュー、それから：

変化：

tell application "System Preferences" to ¬
    reveal anchor "Seeing_Zoom" of ¬
        pane id "com.apple.preference.universalaccess"

に：

tell application "System Preferences"
    reveal anchor "Seeing_Zoom" of ¬
        pane id "com.apple.preference.universalaccess"
    activate
end tell

_{注:例 AppleScript コードそれだけで何も含まれていないエラー処理追加のエラー処理必要に応じて追加する責任はユーザーにあります。エラー処理適切、必要、または望まれる場合。試す声明そしてエラー声明の中にAppleScript 言語ガイド参照:エラーの処理さらに、遅れ指示delay 0.5適切な場合にはイベント間での中断が必要になる場合があります。価値の遅れ適切に設定してください。}

Answer 1