☰

Wie bekomme ich mit Deluge Magnet-Links oder ist das überhaupt möglich?

tag-icon • tag-icon deluge
Wie bekomme ich mit Deluge Magnet-Links oder ist das überhaupt möglich?

Sie sagen, es ist nicht mehr kompatibel? Warum ist die Info-Hash-Schaltfläche ausgegraut?

Weiß jemand, wie ich mit dem Deluge Web UI Client Magnet-Links bekomme?

Übrigens, meine Deluge-Client-Version ist 1.3.5

Antwort1

EntsprechendFragenUbuntu, Magnet-Unterstützung in der WebUI wurde im Mai in 1.3.4 hinzugefügt. Sind Sie sicher, dass Sie auf dem neuesten Stand sind?

Antwort2

Ich klicke mit der rechten Maustaste auf den Magnet-Link und wähle „Linkadresse kopieren“ oder Ähnliches und kopiere diesen Link dann in Deluge unter „Torrent hinzufügen“.

Antwort3

Für den Mac, GitHub-BenutzerHerr-Kaminhat geschriebenSprühflut-Magnet-Handler, ein AppleScript-Workaround. Wird im Ordner „Programme“ installiert und einmal ausgeführt, um sich mit magnet:Links zu verknüpfen. Danach sollten diese URLs automatisch in Deluge geöffnet werden.

on quit
    try
        tell application "System Events" to tell process "Deluge"
            activate
            set frontmost to true
            windows where title contains "Add Torrents"
            if result is not {} then perform action "AXRaise" of item 1 of result
        end tell
    end try
end quit

on open location this_URL
    try
        tell application "Finder" to set delugePath to POSIX path of (application file id "org.deluge" as string)
        set appExists to true
    on error
        set appExists to false
        display alert "Deluge.app must be installed in order to use this plug-in." as critical
        return
    end try
    set delugeArgument to quoted form of this_URL
    try
        tell application "Deluge" to activate
    end try
    do shell script (quoted form of (delugePath & "/Contents/MacOS/Deluge") & " add " & delugeArgument & "; return;")
    quit
end open location
tell application "Finder" to set thisPath to (POSIX path of (application file id "org.deluge.MagnetURIHandler" as string))
log thisPath
set lsToolRead to do shell script (quoted form of (thisPath & "/Contents/Resources/lstool") & " read url magnet")
if (lsToolRead contains "Magnet Handler.app") then
    display dialog "Magnet Handler is already the default application to handle magnet URIs" buttons {"OK"} with title "Notification" with icon POSIX file (thisPath & "/Contents/Resources/deluge_magnet.icns")
else
    try
        set dialogResult to display dialog "Magnet Handler has not been configured to handle magnet URIs.

Would you like to do this now?" buttons {"Yes", "No"} default button "Yes" cancel button "No" with title "Notification" with icon POSIX file (thisPath & "/Contents/Resources/deluge_magnet.icns")
    on error number -128
    end try
    try
        if button returned of dialogResult is "Yes" then
            do shell script (quoted form of (thisPath & "/Contents/Resources/lstool") & " write url magnet org.deluge.MagnetURIHandler")
            display dialog "Magnet Handler has now been configured as the default application to handle magnet URIs" buttons {"OK"} with title "Notification" with icon POSIX file (thisPath & "/Contents/Resources/deluge_magnet.icns")

        end if
    end try
end if
quit

verwandte Informationen