Batch-Datei zum Verschieben aller Dateien von einem Ort zum anderen in Windows?

Question

was ich suche, ist eine Batchdatei, die alle Dateien von einem Ordner in einen anderen verschiebt, mit der Möglichkeit, dies als Aufgabe zu planen, die zweimal täglich ausgeführt wird.

Ich kenne den gesamten Verschiebebefehl usw., aber es scheint sich um eine Datei nach der anderen oder den Ordner selbst zu handeln

Der Ordner muss dort bleiben, die darin enthaltenen Dateien müssen jedoch verschoben werden.

Grüße, Kyle

Answer 1

Das folgende Skript könnte helfen:

@ECHO OFF >NUL
SETLOCAL enableextensions
set "folderIn=D:\test\Files In"
set "folderOu=D:\test\Files Out"
set "logFile=%folderOu%\movelog.txt"
set "logToDo=>> "%logFile%" 2>&1"
rem above line causes that moved file names will be logged to file %logFile%
rem unrem next line if you need no log 
rem set "logToDo="
set /A "filesInNo=0"
for /f "tokens=*" %%# in ('dir /B "%folderIn%\*.*" 2^>NUL') do set /A "filesInNo+=1"
(
  echo === %date% %time% === %filesInNo%
  if %filesInNo% GTR 0 (
      move /Y "%folderIn%\*.*" "%folderOu%\"
  ) else (
      rem Nothing to copy
  )
)%logToDo%
rem next line for debugging purposes only
if not "%*"=="" type "%logFile%"
ENDLOCAL
goto :eof

Erläuterungen finden Sie in remden Kommentaren undRessourcen(Pflichtlektüre):

• (Befehlsreferenz)Ein AZ-Index der Windows CMD-Befehlszeile
• (weitere Besonderheiten)Befehlszeilensyntax der Windows CMD-Shell
• ( %~#usw. Sonderseite)Befehlszeilenargumente (Parameter)
• ( >>, 2>&1usw. Spezialseite)Umleitung