☰

bat-Datei zum Aktivieren oder Deaktivieren der Proxy-Verwendung auf dem PC

tag-icon • tag-icon windows proxy internet-explorer batch-file
bat-Datei zum Aktivieren oder Deaktivieren der Proxy-Verwendung auf dem PC

Es ist diese Zeit des Tages. Sie verlassen das Büro und setzen sich nach Hause. Schalten Sie Ihren Laptop ein. Sie müssen die Verwendung des Proxys auf PC-Ebene über Systemsteuerung > Internetoptionen > Verbindungen > Proxy aus deaktivieren. Am nächsten Morgen dasselbe im Büro. Wiederholen Sie all dies, um es wieder zu aktivieren. Suchen Sie anschließend unter Ausführen nach inetcpl.cpl, um sicherzustellen, dass Sie diesen Dialog einfacher erreichen. Aktivieren/deaktivieren Sie ihn und sagen Sie OK.

es ist ärgerlich, ich wollte eine Bat-Datei oder einen Registrierungsschlüssel haben, um dies mit einem Klick zu erledigen, anstatt es jedes Mal zu tun! Nach zu vielen Suchen und dem Ausprobieren vieler Szenarien hat nichts funktioniert.

Ich weiß, dass Browser Add-Ons zum Aktivieren/Deaktivieren des Proxy-Proxys haben und in Chrome usw. gut funktionieren, aber damit alles funktioniert, muss dies über die Internetoptionen erfolgen, damit es auf PC-Ebene verfügbar ist …

Jede funktionierende Idee ist willkommen

Danke

Antwort1

Ohne Worte :-)

:: EnableProxy
@Echo off
set "Key=HKCU\Software\Microsoft\Windows\CurrentVersion\Internet Settings"
Set "Val=ProxyEnable"
Set "Typ=REG_DWORD"
Reg add "%Key%" /v %Val% /t %Typ% /d "0x1" /f


:: Disable Proxy
@Echo off
set "Key=HKCU\Software\Microsoft\Windows\CurrentVersion\Internet Settings"
Set "Val=ProxyEnable"
Set "Typ=REG_DWORD"
Reg add "%Key%" /v %Val% /t %Typ% /d "0x0" /f


:: ToggleProxy.cmd
@Echo off
set "Key=HKCU\Software\Microsoft\Windows\CurrentVersion\Internet Settings"
Set "Val=ProxyEnable"
Set "Typ=REG_DWORD"
for /f "tokens=3" %%R in (
  'Reg Query "%Key%" /v %Val% ^|find /i "%Val%"'
) do if "%%~R" equ "0x0" (
   Reg add "%Key%" /v %Val% /t %Typ% /d "0x1" /f
) else (
   Reg add "%Key%" /v %Val% /t %Typ% /d "0x0" /f
)

Ich habe einen ähnlichen Artikel auf StackOverflow geschrieben, umzwischen zwei verschiedenen Proxys umschalten.

verwandte Informationen