활성 창 AHK 스크립트 주변의 빨간색 테두리를 미세 조정하세요.

Question 1

이해하기 쉽도록 변수 이름을 바꾸는 것이 좋습니다. 명령문 WinSet은 x/y 좌표 쌍으로 두 개의 상자를 그리므로 x/y 좌표 쌍으로 변수 이름을 지정하고 명령문 앞에 할당하는 것이 WinSet덜 혼란스럽습니다.

이 특정 예에서는 창 외부 주위에 테두리도 그립니다. 창 바깥쪽이 화면 가장자리에 있을 때 테두리는 화면 밖에 있으므로 보이지 않습니다. 테두리가 화면 가장자리에 있을 때(또는 바깥쪽에 있을 때) 화면에 그리려면 창 경계 내부(또는 부분적으로 내부)에 테두리를 그리는 것이 아니라 창 경계 외부에 테두리를 그려야 합니다. .

이는 부분적인 해결책일 뿐입니다. 왜냐하면 최대화된 상태에서는 창이 단순히 가장자리에 있는 것보다 화면에서 훨씬 더 멀리 떨어져 있기 때문입니다. 이 경우 최대화된 조건을 감지하고 특정 수의 픽셀만큼 일반적인 것보다 훨씬 더 경계를 오프셋해야 합니다.

변수 이름을 바꾸고 코드를 수정하여 예제를 제공했습니다. 효과를 확인하기 위해 다양한 '테두리 유형'을 변경할 수 있습니다. 다르게 그리려면 나머지는 단지 수학일 뿐입니다.

#Persistent

SetTimer, DrawRect, 50
border_thickness = 5
border_color = FF0000

DrawRect:
WinGetPos, x, y, w, h, A
if (x="")
    return
Gui, +Lastfound +AlwaysOnTop +Toolwindow

borderType:="inside"                ; set to inside, outside, or both

if (borderType="outside") { 
    outerX:=0
    outerY:=0
    outerX2:=w+2*border_thickness
    outerY2:=h+2*border_thickness

    innerX:=border_thickness
    innerY:=border_thickness
    innerX2:=border_thickness+w
    innerY2:=border_thickness+h

    newX:=x-border_thickness
    newY:=y-border_thickness
    newW:=w+2*border_thickness
    newH:=h+2*border_thickness

} else if (borderType="inside") {   
    WinGet, myState, MinMax, A
    if (myState=1)
        offset:=8
    else 
        offset:=0

    outerX:=offset
    outerY:=offset
    outerX2:=w-offset
    outerY2:=h-offset

    innerX:=border_thickness+offset
    innerY:=border_thickness+offset
    innerX2:=w-border_thickness-offset
    innerY2:=h-border_thickness-offset

    newX:=x
    newY:=y
    newW:=w
    newH:=h



} else if (borderType="both") { 
    outerX:=0
    outerY:=0
    outerX2:=w+2*border_thickness
    outerY2:=h+2*border_thickness

    innerX:=border_thickness*2
    innerY:=border_thickness*2
    innerX2:=w
    innerY2:=h

    newX:=x-border_thickness
    newY:=y-border_thickness
    newW:=w+4*border_thickness
    newH:=h+4*border_thickness
}



Gui, Color, %border_color%
Gui, -Caption

;WinSet, Region, 0-0 %w%-0 %w%-%h% 0-%h% 0-0 %border_thickness%-%border_thickness% %iw%-%border_thickness% %iw%-%ih% %border_thickness%-%ih% %border_thickness%-%border_thickness%
 WinSet, Region, %outerX%-%outerY% %outerX2%-%outerY% %outerX2%-%outerY2% %outerX%-%outerY2% %outerX%-%outerY%    %innerX%-%innerY% %innerX2%-%innerY% %innerX2%-%innerY2% %innerX%-%innerY2% %innerX%-%innerY% 


;Gui, Show, w%w% h%h% x%x% y%y% NoActivate, Table awaiting Action
Gui, Show, w%newW% h%newH% x%newX% y%newY% NoActivate, Table awaiting Action
return

또한 참고로, 창 이동 이벤트에 대해 Windows 콜백 이벤트를 연결하는 방법도 있으므로 항상 업데이트되는 50ms 타이머를 사용할 필요가 없습니다. 이 경우 창이 움직일 때만 업데이트되며 타이머에는 눈에 띄는 지연과 처리 오버헤드가 발생합니다. 그러나 타이머는 (이미 수행한 것처럼) 게이트 외부에서 구현하기 훨씬 쉬운 솔루션이며, 많은 경우 필요하지 않은 경우 창 이벤트를 연결하는 데 추가 복잡성을 감당할 가치가 없습니다. 그래도 가능하다는 점을 알려드립니다.

Answer