☰

Compactando vários arquivos em vários arquivos?

tag-icon • tag-icon compression archiving winrar
Compactando vários arquivos em vários arquivos?

Tenho uma pasta cheia de pdfs e cansei de fazer o Winraring de cada arquivo separadamente. Não quero colocá-los todos em um arquivo.

Não existe uma linha de comando que eu possa usar para fazer o Winrar compactar um arquivo com o melhor método, excluir o arquivo depois de fazer o .rar e fazer o mesmo para o próximo arquivo?

Responder1

Sim, existe um executável rar.exe na pasta de instalação do WinRAR. Executá-lo sem parâmetros mostra ajuda completa sobre seu uso. Por exemplo, você define o melhor nível de compactação com a opção -m5.

Como foi dito, script em lote/shell é uma boa maneira de fazer isso, mas você pode achar interessante este projeto com objetivos semelhantes:http://code.google.com/p/autorar/.

Responder2

Este é um script que escrevi para compactar cada arquivo separadamente com o arquivador rar (formato winrar5). Para compactar todos os arquivos *.pdf em uma pasta separadamente, você deve colocar este script em um arquivo .bat e executá-lo. Primeiro você especifica um diretório inicial (raiz) onde seus arquivos estão localizados, então você pode especificar extensões para localizar e compactar nesse diretório (pesquisa recursiva, inserindo subdiretórios do diretório raiz)

@echo off

REM -m5 max compression    
REM -md64m dictionary size 64m
REM -s solid
REM -ma5 rar5 format (rar4 - ma4)
REM -y yes to all
REM -t test after packing (if test NOT ok, then files will not be deleted if the -df/-dr specified)
REM -df delete files after successful archivation
REM -ep1 exclude base folder of file from archive
:: %%~nZ - file name extracted from var Z
:: %%~fZ - full path of file+ext from var Z
:: %%~dpZ - disk+path
:: setlocal - use local environment vars
setlocal

:step1
    echo Enter start path where files a located
    set /p rarpath=
    echo.
    :: remove doublequotes from path
    set rarpath=%rarpath:"=%

:check dir exist
    if not exist "%rarpath%" echo   "!!!  [%rarpath%] doesn't exist, please enter correct path  !!!"
    if not exist "%rarpath%" echo.
    if not exist "%rarpath%" goto step1
:::::
:::::
    echo.
    echo Enter which extensions to compress (like *.mp4;*.wmv)
    set /p exten=
    echo.
:::::
:::::
    echo.
    echo Final command: 
    echo for /R "%rarpath%" %%Z in (%exten%) do "%programfiles%\WinRAR\rar.exe" a -ma5 -m5 -s -md64m -t -y -ep1 -df "%%~nZ.rar" "%%~fZ"
    echo.
:::::
:::::
    echo.
    echo Continue? [y/n]
    set /p go=
    if /i %go%==Y goto ok
    if /i %go%==N goto exit

:ok
:: CD to each file's directory, compress file, log output (codepage 866)
set rartime=%time:~0,8%
set rartime=%rartime::=_%
set rartime=%rartime: =%
set rarlog=rar_log_%date%_%rartime%.txt
:: For directories located in current directory
:: for /d %D in (*) do "%programfiles%\winrar\rar.exe" a -ma5 -m5 -s -md64m -t -y -ep1 -df "%D.rar" "%D"

    for /R "%rarpath%" %%Z in (%exten%) do (
        cd /d %%~dpZ
        "%programfiles%\WinRAR\rar.exe" a -ma5 -m5 -s -md64m -t -y -ep1 -df "%%~nZ.rar" "%%~fZ" >> c:\%rarlog% 2>&1
        type c:\%rarlog%
        echo. >> c:\%rarlog%
        echo ----------------------------------------------------------------------------- >> c:\%rarlog%
        echo. >> c:\%rarlog%
    )
    echo.
    echo.
    echo        !!! All Done !!!
    pause
    goto :EOF
    ::EXIT /B 0

:exit
    echo Program terminated
    pause
    goto :EOF

informação relacionada