Usando tikz para transformar uma única letra

Question

Quero transformar uma letra em uma página de título de uma forma muito específica. Para ilustrar o efeito que estou tentando obter, anexei uma imagem. Observe como a metade esquerda da letra H é mais curta que a metade direita, mas o topo da letra está nivelado. Suspeito que vou querer distorcê-lo de alguma forma usando o tikz, mas não tenho certeza de como conseguiria isso. Alguém pode ajudar?

Answer 1

Isenção de responsabilidade:Esta NÃO é uma resposta do TikZ, mas tanto faz ...

TirandoA resposta de Thruston a esta pergunta sobre contornos de textocomo referência, você poderia fazer o seguinte para obter uma letra H deformada. É uma prova de conceito, por isso só funciona com letras individuais, mas é possível adaptá-lo a palavras completas com mais ajustes.

\documentclass{standalone}
\usepackage[latex,shellescape]{gmp}
\begin{document}
\begin{mpost}[name=H]
picture nice;
path P, PP;

nice := image(draw thelabel(\btex H etex,origin));

%Transformation
vardef T(expr p) =
    save x, y;
    x := xpart p; y := ypart p;
%0.01 by guessing. Play with other values
    (x,0.01x*y) 
enddef;

%Assumes a cyclic path
%It can be done better
vardef TT(expr P) =
    T(point 0 of P) 
    .. controls
    T(postcontrol 0 of P) and T(precontrol 1 of P) 
    for j = 1 upto (length P - 1):
        .. T(point j of P) 
        .. controls T(postcontrol j of P) 
            and T(precontrol (j+1) of P) 
    endfor
    .. cycle
enddef;

for i within nice:
    if textual i:
        for j = 1 upto length textpart i:
            string s; s := substring(j-1,j) of textpart i;
            picture g; g := glyph ASCII s of fontpart i scaled 1/10;
            picture r; r := image(
            for x within g:
                picture xx; xx := image(draw g);
%75 is also guessing. Try other values
%Bad filling. It works for the letter H, tho.
                fill TT(pathpart x shifted (llcorner xx - ulcorner xx + 75right)) withcolor
                if greypart x = 1:
                    1
                else:
                    (1,0.843,0)
                fi;
            endfor
            );
            draw r;
        endfor 
    fi
endfor
\end{mpost}\usempost{H}%
\end{document}

Para efeito de comparação, este é o resultado para a letra Q (aplica um preenchimento falso):