Intersecção da reta de um triângulo com outra reta que passa pelo vértice oposto e pelo circuncentro

Question

Eu tenho o seguinte código:

      pair a; pair b; pair c;
      pickup pencircle scaled 0.2pt;
      a = (0, 4cm); b = (-2cm, 0); c = (1cm, 0);
      draw a -- b -- c -- cycle;
      pair p; pair q; pair r; pair d; pair m; pair n;
      p = whatever[b, c]; a - p = whatever * (b - c) rotated 90;
      q = whatever[c, a]; b - q = whatever * (c - a) rotated 90;
      r = whatever[a, b]; c - r = whatever * (a -b) rotated 90;
      d = whatever[a, p] = whatever[b, q]; % orthocenter
      n = 1/4(a + b + c + d); % remarkably...
      m = d rotatedabout(n, 180); % M is also the circumcentre
      path circumcircle;
      circumcircle = fullcircle scaled 2 abs(m - a) shifted m;
      draw circumcircle;
      pair l;
      pickup pencircle scaled 2pt;
      drawdot m;
      pickup pencircle scaled 0.2pt;
      %draw a -- ((a -- m) intersectionpoint (b -- c));

Posso calcular o circuncentro e funciona. Mas a última linha comentada, quando não comentada, me diz que os caminhos não se cruzam. É o caso que AMnão é estendido para cálculo de intersecção com BC? Acho que consigo fazer isso com shiftedpalavras-chave, mas não sei como. Qualquer ajuda será muito apreciada.

Answer 1

Consegui alterar a última linha para a seguinte:

draw a -- (a -- (a - 100(a - m))) intersectionpoint (b -- c);

e pegue a linha. Parece que essa linha precisa ser estendida para intersectionpointfuncionar.

Answer 2

Se quiser seguir o mesmo estilo do seu código anterior, você também pode fazer

pair q ; q = whatever[a,m] = whatever[b,c] ;
draw a -- q ;