Как сделать стрелку из частей формулы в Asymptote? (или: измерить ширину метки, получить якорь вокруг метки)

Question

Подводя итог: я хочу нарисовать следующую фигуру в Асимптоте.

Мой код выглядит следующим образом.

size(5cm);
draw(scale(8, 4)*unitsquare);
label("$\underbrace{123}+\underbrace{456}=\underbrace{789}$", (4, 3));
draw((2.1, 2.5)--(1, 1), Arrow);
draw((3.95, 2.5)--(4, 1), Arrow);
draw((5.9, 2.5)--(7, 1), Arrow);
label("\strut$a$", (1, 1.1), S);
label("\strut$b$", (4, 1.1), S);
label("\strut$c$", (7, 1.1), S); // \strut is used to make the baselines horizontally aligned.

Проблема: В трех drawстроках координата x начальной точки стрелок жестко закодирована.

Как можно автоматически вычислить местоположение начала стрелки по положению кончика подкоса?

(Было бы полезно вычислить ширину этикетки, но я не понимаю, как это сделать.)

Что-то похожее на tikzmarkфункцию, показанную на рисункеhttps://tex.stackexchange.com/a/145696/250119Это помогло бы, но я не знаю о такой функции в Asymptote.

Answer 1

Частичное решение. Несколько адаптировано изhttps://sourceforge.net/p/asymptote/discussion/409349/thread/3fc73fb8/.

Если подумать, размер метки относительно координат пользователя не определяется до самого конца программы --- что определенно вызывает проблему. Так что это лишь частичное решение, котороепредполагается, unitsizeчто это фиксировано.

По сути, он создает 5 объектов-меток, затем каждый объект помещается в picture, затем его размер измеряется с помощью , min()/max()/size()чтобы определить середину нижнего края коробки.

Обратите внимание, что для того, чтобы min()etc. возвращали правильное значение, unitsize()необходимо правильно настроить суб-изображение.

К сожалению,этот метод нарушает интервал--- Я не уверен, как это можно исправить.

var unitsize=1cm;
unitsize(unitsize);

string template="$\underbrace{1}$";

picture a;
unitsize(a, unitsize);
// draw the labels, and compute the coordinate of the bottom points along the way
label(a, baseline("$\underbrace{123}$", template), (0, 0), align=NE);
pair bottom1=((min(a, user=true).x+max(a, user=true).x)/2, min(a, user=true).y);
label(a, baseline("$+$", template), (max(a, user=true).x, 0), align=NE);
real u=max(a, user=true).x;
label(a, baseline("$\underbrace{456}$", template), (max(a, user=true).x, 0), align=NE);
pair bottom2=((u+max(a, user=true).x)/2, min(a, user=true).y);
label(a, baseline("$=$", template), (max(a, user=true).x, 0), align=NE);
real u=max(a, user=true).x;
label(a, baseline("$\underbrace{789}$", template), (max(a, user=true).x, 0), align=NE);
pair bottom3=((u+max(a, user=true).x)/2, min(a, user=true).y);

// compute shift such that the text is centered at x = 4
pair ashift=(4-size(a, user=true).x/2, 3);

// draw the text on currentpicture
add(shift(ashift)*a);

// some other text for comparison
label("$\underbrace{123}+\underbrace{456}=\underbrace{789}$", (4, 4), align=N);
label("$123+456=789$", (4, 5), align=N);

// draw the arrows
draw(ashift+bottom1--(1, 1), Arrow);
draw(ashift+bottom2--(4, 1), Arrow);
draw(ashift+bottom3--(7, 1), Arrow);
label(baseline("$a$"), (1, 1.1), S);
label(baseline("$b$"), (4, 1.1), S);
label(baseline("$c$"), (7, 1.1), S);

Выход: